[arch-commits] Commit in intel-media-sdk/repos (2 files)

[Daniel Bermond]

    Date: Thursday, October 29, 2020 @ 15:02:00
  Author: dbermond
Revision: 736524

archrelease: copy trunk to community-staging-x86_64

Added:
  intel-media-sdk/repos/community-staging-x86_64/
  intel-media-sdk/repos/community-staging-x86_64/PKGBUILD
    (from rev 736523, intel-media-sdk/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: intel-media-sdk/repos/community-staging-x86_64/PKGBUILD (from rev 736523, intel-media-sdk/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-10-29 15:02:00 UTC (rev 736524)
@@ -0,0 +1,59 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+
+pkgbase=intel-media-sdk
+pkgname=('intel-media-sdk' 'libmfx')
+pkgver=20.3.1
+pkgrel=1
+pkgdesc='API to access hardware-accelerated video on Intel Gen graphics hardware platforms'
+arch=('x86_64')
+url='https://software.intel.com/en-us/media-sdk/'
+license=('MIT')
+makedepends=('libdrm' 'libva' 'wayland' 'intel-media-driver'
+             'cmake' 'libpciaccess' 'libx11' 'libxcb' 'python'
+             'opencl-headers' 'opencl-clhpp' 'ocl-icd' 'intel-compute-runtime')
+source=("https://github.com/Intel-Media-SDK/MediaSDK/archive/intel-mediasdk-${pkgver}.tar.gz")
+sha256sums=('8ed7ca8c638504b5f80ff289518fdd2a1bd8a2d33fad949c30ee893f599c9952')
+
+build() {
+    cmake -B build -S "MediaSDK-intel-mediasdk-${pkgver}" \
+        -DBUILD_ALL:BOOL='ON' \
+        -DBUILD_TOOLS:BOOL='ON' \
+        -DCMAKE_BUILD_TYPE:STRING='None' \
+        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
+        -DENABLE_ITT:BOOL='OFF' \
+        -DENABLE_OPENCL:BOOL='ON' \
+        -DENABLE_WAYLAND:BOOL='ON' \
+        -DENABLE_X11_DRI3:BOOL='ON' \
+        -Wno-dev
+    make -C build
+}
+
+check() {
+    make -C build test
+}
+
+package_intel-media-sdk() {
+    depends=('libdrm' 'libva' 'wayland' "libmfx=${pkgver}" 'intel-media-driver')
+    optdepends=('ocl-icd: for rotate_opencl plugin'
+                'intel-compute-runtime: for rotate_opencl plugin')
+    
+    make -C build DESTDIR="$pkgdir" install
+    ln -s ../share/mfx/samples/libcttmetrics.so "${pkgdir}/usr/lib/libcttmetrics.so"
+    install -D -m644 "MediaSDK-intel-mediasdk-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+    
+    # remove core component libmfx
+    [ -d 'libmfx' ] && rm -rf libmfx
+    mkdir -p libmfx/{include,lib/pkgconfig}
+    mv "${pkgdir}/usr/include/mfx" libmfx/include
+    mv "${pkgdir}/usr/lib/libmfx.so"* libmfx/lib
+    mv "${pkgdir}/usr/lib/pkgconfig/"{,lib}mfx.pc libmfx/lib/pkgconfig
+    rm -d "${pkgdir}/usr/include"
+}
+
+package_libmfx() {
+    pkgdesc='Intel Media SDK dispatcher library'
+    depends=('gcc-libs')
+    
+    mv libmfx "${pkgdir}/usr"
+    install -D -m644 "MediaSDK-intel-mediasdk-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}