[arch-commits] Commit in (5 files)
Alexander Rødseth
arodseth at archlinux.org
Fri Oct 30 11:09:05 UTC 2020
Date: Friday, October 30, 2020 @ 11:09:04
Author: arodseth
Revision: 736682
Add a terminal Gemini browser
Added:
amfora/
amfora/repos/
amfora/repos/community-x86_64/
amfora/trunk/
amfora/trunk/PKGBUILD
----------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
Added: amfora/trunk/PKGBUILD
===================================================================
--- amfora/trunk/PKGBUILD (rev 0)
+++ amfora/trunk/PKGBUILD 2020-10-30 11:09:04 UTC (rev 736682)
@@ -0,0 +1,42 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Paul Boyd <boyd.paul2 at gmail.com>
+
+pkgname=amfora
+pkgver=1.5.0
+pkgrel=3
+pkgdesc='Terminal browser for the Gemini protocol'
+arch=(x86_64)
+url='https://github.com/makeworld-the-better-one/amfora'
+license=(GPL3)
+makedepends=(git go)
+source=("git+$url#commit=922e7981a92cb7bf0d7b3baf1694d0fffe90d448" # tag: v1.5.0
+ 'https://roboticoverlords.org/amfora.png')
+sha256sums=('SKIP'
+ '3d029d05cff8c42e82685ce7a61fcaa2118e4cbb6a547816a7d5150868a11092')
+
+prepare() {
+ echo 'Icon=amfora' >> "$pkgname/amfora.desktop"
+}
+
+build() {
+ cd $pkgname
+ #export CGO_CPPFLAGS="$CPPFLAGS"
+ #export CGO_CFLAGS="$CFLAGS"
+ #export CGO_CXXFLAGS="$CXXFLAGS"
+ #export CGO_LDFLAGS="$LDFLAGS"
+ go build \
+ -buildmode=pie \
+ -ldflags "-s -w -linkmode=external -extldflags $LDFLAGS -X main.version=$pkgver -X main.builtBy=Arch_Linux -X main.commit=${source#*=}" \
+ -mod=readonly \
+ -modcacherw \
+ -trimpath \
+ -v
+}
+
+package() {
+ cd $pkgname
+ install -Dm755 amfora "$pkgdir/usr/bin/amfora"
+ install -Dm644 amfora.desktop "$pkgdir/usr/share/applications/amfora.desktop"
+ install -Dm644 "$srcdir/amfora.png" "$pkgdir/usr/share/pixmaps/amfora.png"
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
More information about the arch-commits
mailing list