[arch-commits] Commit in (4 files)
Frederik Schwan
freswa at archlinux.org
Fri Oct 30 17:13:52 UTC 2020
Date: Friday, October 30, 2020 @ 17:13:52
Author: freswa
Revision: 736786
move perl-par-packager from unsupported to [community]
Added:
perl-par-packer/
perl-par-packer/repos/
perl-par-packer/trunk/
perl-par-packer/trunk/PKGBUILD
----------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
Added: perl-par-packer/trunk/PKGBUILD
===================================================================
--- perl-par-packer/trunk/PKGBUILD (rev 0)
+++ perl-par-packer/trunk/PKGBUILD 2020-10-30 17:13:52 UTC (rev 736786)
@@ -0,0 +1,42 @@
+# Maintainer: Frederik Schwan <freswa at archlinux dot org>
+# Contributor: Amish <contact at via dot aur>
+# Contributor: Justin Davis <jrcd83 at gmail.com>
+# Contributor: Tony Sokhon <tonyskn at gmail.com>
+
+pkgname=perl-par-packer
+pkgver=1.050
+pkgrel=5
+pkgdesc='PAR Packager'
+arch=('x86_64')
+url='https://metacpan.org/release/PAR-Packer'
+license=('GPL')
+# This package links agains libperl.so
+depends=('perl=5.32.0' 'perl-archive-zip' 'perl-getopt-argvfile' 'perl-ipc-run3' 'perl-module-scandeps'
+ 'perl-par' 'perl-par-dist')
+makedepends=('perl-extutils-makemaker')
+options=('!emptydirs' purge)
+source=("https://cpan.metacpan.org/authors/id/R/RS/RSCHUPP/PAR-Packer-${pkgver}.tar.gz")
+b2sums=('9f7702ef38d6c21fc4df6d4a2dbc432c6d64cee99cda707a7e9197aa4d7e276210b9095da92cb1767275eba6e7671b6410b95e082d579972bab97cba48a365bf')
+
+build() {
+ cd PAR-Packer-${pkgver}
+ unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+ export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+ perl Makefile.PL
+ make
+}
+
+check() {
+ cd PAR-Packer-${pkgver}
+ unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+ export PERL_MM_USE_DEFAULT=1
+ make test
+}
+
+package() {
+ cd PAR-Packer-${pkgver}
+ unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
+ make install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
+ #remove conflicting and empty man page
+ rm "${pkgdir}"/usr/share/man/man1/pp.1
+}
More information about the arch-commits
mailing list