[arch-commits] Commit in picard/trunk (PKGBUILD)

[David Runge]

    Date: Wednesday, September 2, 2020 @ 22:39:33
  Author: dvzrv
Revision: 697193

upgpkg: picard 2.4.2-1: Upgrade to 2.4.2.

Remove unused validpgpkeys (the only one mentioned is 1024bit DSA - https://tickets.metabrainz.org/browse/PICARD-1934).
Open upstream ticket about missing tests in pypi sdist tarball.
Switch to correct license (GPL2).
Add all direct depedencies in depends.
Build from release tarball instead of cloning from commit without verification.
Run tests in check() using pytest.
Skip build in package() and install docs.
Update maintainer info.

Modified:
  picard/trunk/PKGBUILD

----------+
 PKGBUILD |   58 +++++++++++++++++++++++++++++++++++-----------------------
 1 file changed, 35 insertions(+), 23 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2020-09-02 22:32:21 UTC (rev 697192)
+++ PKGBUILD	2020-09-02 22:39:33 UTC (rev 697193)
@@ -1,37 +1,49 @@
-# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Gaetan Bisson <bisson at archlinux.org>
 # Contributor: Mateusz Herych <heniekk at gmail.com>
 # Contributor: sysrq
 
 pkgname=picard
-pkgver=2.4.1
-pkgrel=3
-pkgdesc='Official MusicBrainz tagger'
-url='https://picard.musicbrainz.org/'
-license=('GPL')
+pkgver=2.4.2
+pkgrel=1
+pkgdesc="Official MusicBrainz tagger"
+url="https://github.com/metabrainz/picard"
+license=('GPL2')
 arch=('x86_64')
-depends=('python-pyqt5' 'python-mutagen' 'python-dateutil')
+depends=('glibc' 'python-dateutil' 'python-discid' 'python-markdown'
+'python-mutagen' 'python-pyqt5')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest')
 optdepends=('chromaprint: fingerprinting'
-            'python-discid: cd lookup'
-            'python-markdown: doc rendering'
             'qt5-multimedia: media player toolbar'
             'qt5-translations: full UI translation')
-makedepends=('git' 'python-setuptools')
-#source=("git+https://github.com/metabrainz/picard.git#tag=release-$pkgver?signed")
-source=("git+https://github.com/metabrainz/picard.git#commit=9abd145914561399f0da69b9be93995414007032")
-validpgpkeys=('9FD61CE6F154EC5A3531D0DE23A723D6417E5D5A')
-sha256sums=('SKIP')
+# pypi sdist tarball does not contain tests
+# https://tickets.metabrainz.org/browse/PICARD-1935
+# source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/${pkgname}/${pkgname}-${pkgver}.tar.gz")
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/metabrainz/${pkgname}/archive/release-${pkgver}.tar.gz")
+sha512sums=('17f6015dd06a1282e6dc216726a74cc7bf2a54a5694e09e2d7ae6f1b4c85f2f60f3de1218d952fa2c4e088b3330d1fd12e4b41cf819d7c3d2d96278532338e15')
+b2sums=('a44e82ac1a0ad776eb371309ad13f0a5e9afe4a0fe8b898dbbcb71ac554da3ff7cf4a2d88a8e476c811dfeb515ca7371ca8effb326b9285e6c53ebeac6795c15')
 
+prepare() {
+  mv -v "${pkgname}-release-${pkgver}" "${pkgname}-${pkgver}"
+}
+
 build() {
-	cd "${srcdir}/${pkgname}"
-	sed "s/‘/'/g" -i setup.cfg
-	python setup.py config
+  cd "${pkgname}-${pkgver}"
+  python setup.py build
 }
 
+check() {
+  cd "${pkgname}-${pkgver}"
+  pytest -v
+}
+
 package() {
-	cd "${srcdir}/${pkgname}"
-	python setup.py install \
-		--root="${pkgdir}" \
-		--disable-autoupdate \
-
-	rm -fr "${pkgdir}"/usr/lib/python*/site-packages/picard-*.egg-info
+  cd "${pkgname}-${pkgver}"
+  python setup.py install --skip-build \
+                          --optimize=1 \
+                          --disable-autoupdate \
+                          --root="${pkgdir}"
+  install -vDm 644 {AUTHORS.txt,{CONTRIBUTING,NEWS,README}.md} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}"
 }