[arch-commits] Commit in haskell-turtle/repos (2 files)

Felix Yan felixonmars at archlinux.org
Fri Sep 4 09:20:16 UTC 2020


    Date: Friday, September 4, 2020 @ 09:20:16
  Author: felixonmars
Revision: 698473

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-turtle/repos/community-staging-x86_64/
  haskell-turtle/repos/community-staging-x86_64/PKGBUILD
    (from rev 698472, haskell-turtle/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-turtle/repos/community-staging-x86_64/PKGBUILD (from rev 698472, haskell-turtle/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-09-04 09:20:16 UTC (rev 698473)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=turtle
+pkgname=haskell-turtle
+pkgver=1.5.20
+pkgrel=9
+pkgdesc="Shell programming, Haskell-style"
+url="https://github.com/Gabriel439/Haskell-Turtle-Library"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-wl-pprint' 'haskell-async' 'haskell-clock'
+         'haskell-foldl' 'haskell-hostname' 'haskell-managed' 'haskell-optparse-applicative'
+         'haskell-optional-args' 'haskell-streaming-commons' 'haskell-system-fileio'
+         'haskell-system-filepath' 'haskell-temporary' 'haskell-unix-compat')
+makedepends=('ghc' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('5956f3b83e76ecfb9713b5d987340303eb6276b870af1858579dc2f60d25d7e3c6df2d3b4564b014e380baaea8061d9f43bc02ae307554faa4f201e5aba78603')
+
+prepare() {
+    sed -i 's/]/, "-dynamic"]/' $_hkgname-$pkgver/test/Main.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}


More information about the arch-commits mailing list