[arch-commits] Commit in openimageio/repos (2 files)

[Sven-Hendrik Haase]

    Date: Friday, September 4, 2020 @ 15:40:01
  Author: svenstaro
Revision: 698518

archrelease: copy trunk to community-testing-x86_64

Added:
  openimageio/repos/community-testing-x86_64/
  openimageio/repos/community-testing-x86_64/PKGBUILD
    (from rev 698517, openimageio/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: openimageio/repos/community-testing-x86_64/PKGBUILD (from rev 698517, openimageio/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-09-04 15:40:01 UTC (rev 698518)
@@ -0,0 +1,54 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: SpepS <dreamspepser at yahoo dot it>
+
+pkgname=openimageio
+pkgver=2.1.19.0
+pkgrel=2
+pkgdesc="A library for reading and writing images, including classes, utilities, and applications"
+arch=(x86_64)
+url="http://www.openimageio.org/"
+license=('custom')
+depends=('openexr' 'boost-libs' 'openjpeg2' 'glew' 'libtiff' 'opencolorio' 'intel-tbb' 'libpng' 'libraw' 'libwebp'
+         'fmt' 'pugixml' 'pybind11')
+# TODO: Consider adding these deps: 'openvdb' 'ffmpeg' 'ptex' 'libheif' 'hdf5' 'opencv'
+makedepends=('cmake' 'qt5-base' 'python' 'boost' 'mesa' 'freetype2' 'fontconfig' 'libxrender' 'ninja' 'robin-map')
+optdepends=('qt5-base: iv image viewer'
+            'python: bindings support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenImageIO/oiio/archive/Release-$pkgver.tar.gz"
+        https://patch-diff.githubusercontent.com/raw/OpenImageIO/oiio/pull/2698.patch)
+sha512sums=('5bb7d0198e77bdd5821829bce7ed02be54316fa4ef1e87225eb0ab1108fe6b8163a3ea40549ca7e9d5ef2e7b8b0459bb30be3a761c6f17a558b3cb71eb888787'
+            'c42c5a0098a39072c6b32dbdcc8752e697cbf9d41e5d94b343dd4484e747c88a0682a4138a5463e1412929bc1586c148e543776228227f9f1de6ab3b6ab14912')
+
+prepare() {
+  cd oiio-Release-$pkgver
+
+  patch -Np1 -i "$srcdir"/2698.patch
+}
+
+build() {
+  cd oiio-Release-$pkgver
+
+  cmake \
+      -Bbuild \
+      -GNinja \
+      -DUSE_PYTHON=ON \
+      -DPYTHON_VERSION=3.8 \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DCMAKE_INSTALL_LIBDIR=lib \
+      -DOIIO_BUILD_TESTS=ON \
+      -DOIIO_BUILD_TOOLS=ON \
+      -DBUILD_MISSING_FMT=OFF \
+      -DUSE_EXTERNAL_PUGIXML=ON
+  ninja -C build
+}
+
+package() {
+  cd oiio-Release-$pkgver
+
+  DESTDIR="$pkgdir" ninja -C build install
+
+  # Remove vendored fonts
+  rm -r "$pkgdir"/usr/share/fonts
+
+  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE".md
+}