[arch-commits] Commit in libxkbcommon/repos (3 files)
Jan Steffens
heftig at archlinux.org
Sun Sep 6 21:32:00 UTC 2020
Date: Sunday, September 6, 2020 @ 21:32:00
Author: heftig
Revision: 395531
archrelease: copy trunk to testing-x86_64
Added:
libxkbcommon/repos/testing-x86_64/
libxkbcommon/repos/testing-x86_64/PKGBUILD
(from rev 395530, libxkbcommon/trunk/PKGBUILD)
libxkbcommon/repos/testing-x86_64/fix-test.diff
(from rev 395530, libxkbcommon/trunk/fix-test.diff)
---------------+
PKGBUILD | 83 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
fix-test.diff | 13 ++++++++
2 files changed, 96 insertions(+)
Copied: libxkbcommon/repos/testing-x86_64/PKGBUILD (from rev 395530, libxkbcommon/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2020-09-06 21:32:00 UTC (rev 395531)
@@ -0,0 +1,83 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+# Contributor: Mladen Pejakovic <pejakm at gmail.com>
+
+pkgbase=libxkbcommon
+pkgname=(libxkbcommon libxkbcommon-doc libxkbcommon-x11)
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="Keymap handling library for toolkits and window systems"
+url="https://xkbcommon.org/"
+arch=(x86_64)
+license=(custom)
+makedepends=(xkeyboard-config libxml2 libxcb wayland wayland-protocols doxygen
+ git meson)
+checkdepends=(xorg-server-xvfb libgl python-pytest)
+_commit=12f99d0dfe012c07d82d70296bbcac8a0a8ac0a9 # tags/xkbcommon-1.0.0^0
+source=("git+https://github.com/xkbcommon/libxkbcommon#commit=$_commit"
+ fix-test.diff)
+sha256sums=('SKIP'
+ 'e965cf7516d3158f3de1016e955f804a14b3e514df66520d7919e5289eefde69')
+
+pkgver() {
+ cd $pkgbase
+ git describe --tags | sed 's/^xkbcommon-//;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgbase
+ git apply -3 ../fix-test.diff
+}
+
+build() {
+ arch-meson $pkgbase build
+ meson compile -C build
+}
+
+check() {
+ xvfb-run -a meson test -C build --print-errorlogs
+}
+
+_pick() {
+ local p="$1" f d; shift
+ for f; do
+ d="$srcdir/$p/${f#$pkgdir/}"
+ mkdir -p "$(dirname "$d")"
+ mv "$f" "$d"
+ rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+ done
+}
+
+package_libxkbcommon() {
+ depends=(xkeyboard-config libxml2)
+ optdepends=('libxkbcommon-x11: xkbcli interactive-x11'
+ 'wayland: xkbcli interactive-wayland')
+ provides=(libxkbcommon.so libxkbregistry.so)
+
+ DESTDIR="$pkgdir" meson install -C build
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgbase/LICENSE
+
+ _pick libxkbcommon-doc "$pkgdir"/usr/share/doc
+
+ _pick libxkbcommon-x11 "$pkgdir"/usr/lib/*x11*
+ _pick libxkbcommon-x11 "$pkgdir"/usr/lib/pkgconfig/*x11*
+ _pick libxkbcommon-x11 "$pkgdir"/usr/lib/xkbcommon/*x11*
+ _pick libxkbcommon-x11 "$pkgdir"/usr/include/xkbcommon/*x11*
+ _pick libxkbcommon-x11 "$pkgdir"/usr/share/man/man1/*x11*
+}
+
+package_libxkbcommon-doc() {
+ pkgdesc="API documentation for libxkbcommon"
+
+ mv libxkbcommon-doc/* "$pkgdir"
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgbase/LICENSE
+}
+
+package_libxkbcommon-x11() {
+ pkgdesc="Keyboard handling library using XKB data for X11 XCB clients"
+ depends=(libxkbcommon libxkbcommon.so libxcb)
+ provides=(libxkbcommon-x11.so)
+
+ mv libxkbcommon-x11/* "$pkgdir"
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgbase/LICENSE
+}
Copied: libxkbcommon/repos/testing-x86_64/fix-test.diff (from rev 395530, libxkbcommon/trunk/fix-test.diff)
===================================================================
--- testing-x86_64/fix-test.diff (rev 0)
+++ testing-x86_64/fix-test.diff 2020-09-06 21:32:00 UTC (rev 395531)
@@ -0,0 +1,13 @@
+diff --git i/test/tool-option-parsing.py w/test/tool-option-parsing.py
+index de638d1..367e799 100755
+--- i/test/tool-option-parsing.py
++++ w/test/tool-option-parsing.py
+@@ -170,7 +170,7 @@ def test_invalid_option(tool):
+ # xkbcli --version
+ def test_xkbcli_version(xkbcli):
+ stdout, stderr = xkbcli.run_command_success(['--version'])
+- assert stdout.startswith('0')
++ assert stdout.startswith('1')
+ assert stderr == ''
+
+
More information about the arch-commits
mailing list