[arch-commits] Commit in (3 files)

[Maxime Gauduin]

    Date: Monday, September 7, 2020 @ 10:02:14
  Author: alucryd
Revision: 699526

add cargo-tarpaulin

Added:
  cargo-tarpaulin/
  cargo-tarpaulin/trunk/
  cargo-tarpaulin/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Added: cargo-tarpaulin/trunk/PKGBUILD
===================================================================
--- cargo-tarpaulin/trunk/PKGBUILD	                        (rev 0)
+++ cargo-tarpaulin/trunk/PKGBUILD	2020-09-07 10:02:14 UTC (rev 699526)
@@ -0,0 +1,53 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=cargo-tarpaulin
+pkgver=0.14.3
+pkgrel=1
+pkgdesc='Tool to analyse test coverage of cargo projects'
+arch=(x86_64)
+url=https://github.com/xd009642/tarpaulin
+license=(Apache)
+depends=(
+  gcc-libs
+  glibc
+  libcurl.so
+  openssl
+  zlib
+)
+makedepends=(
+  git
+  rust
+)
+_tag=039a1c5286443a3703f0b489b435388cc932c7f6
+source=(git+https://github.com/xd009642/tarpaulin.git#tag=${_tag})
+b2sums=(SKIP)
+
+pkgver() {
+  cd tarpaulin
+
+  git describe --tags
+}
+
+prepare() {
+  cargo fetch \
+    --locked \
+    --manifest-path tarpaulin/Cargo.toml
+}
+
+build() {
+  cargo build \
+    --release \
+    --frozen \
+    --manifest-path tarpaulin/Cargo.toml
+}
+
+package() {
+  cargo install \
+    --frozen \
+    --offline \
+    --no-track \
+    --path tarpaulin \
+    --root "${pkgdir}"/usr
+}
+
+# vim: ts=2 sw=2 et: