[arch-commits] Commit in easytag/trunk (PKGBUILD)

[David Runge]

    Date: Monday, September 7, 2020 @ 12:02:02
  Author: dvzrv
Revision: 395538

upgpkg: easytag 2.4.3-4: Rebuild to remove ogg vorbis functionality.

Switch to correct license (GPL2).
Remove opus, speex, libvorbis and opusfile from depends/makedepends as a bug in easytag corrupts files:
https://gitlab.gnome.org/GNOME/easytag/-/issues/8
Switch to gnome gitlab for upstream source tarballs.
Run autogen.sh in prepare().
Fix a bug in the test suite by touching a validation file.
Add libnautilus-extension as makedepends to also build nautilus integration.
Add all available sodeps in package() and the respective packages in makedepends.
Add all direct dependencies to depends.
Update maintainer info.

Modified:
  easytag/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++--------------
 1 file changed, 37 insertions(+), 14 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2020-09-07 07:55:00 UTC (rev 395537)
+++ PKGBUILD	2020-09-07 12:02:02 UTC (rev 395538)
@@ -1,4 +1,5 @@
-# Maintainer: Guillaume ALAUX <guillaume at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Guillaume ALAUX <guillaume at archlinux.org>
 # Contributor: Kevin Piche <kevin at archlinux.org>
 # Contributor: Aaron Griffin <aaron at archlinux.org>
 # Contributor: dorphell <dorphell at archlinux.org>
@@ -5,29 +6,51 @@
 
 pkgname=easytag
 pkgver=2.4.3
-pkgrel=3
-pkgdesc='Simple application for viewing and editing tags in audio files'
+pkgrel=4
+pkgdesc="Simple application for viewing and editing tags in audio files"
 arch=('x86_64')
-license=('GPL')
-url='https://wiki.gnome.org/Apps/EasyTAG'
-makedepends=('intltool' 'itstool' 'python')
-depends=('id3lib' 'libid3tag' 'gtk3' 'libvorbis' 'flac' 'speex' 'wavpack' 'taglib'
-         'desktop-file-utils' 'opusfile')
-source=(https://download.gnome.org/sources/${pkgname}/${pkgver:0:3}/${pkgname}-${pkgver}.tar.xz)
-sha256sums=('fc51ee92a705e3c5979dff1655f7496effb68b98f1ada0547e8cbbc033b67dd5')
+url="https://wiki.gnome.org/Apps/EasyTAG"
+license=('GPL2')
+# TODO: add back opus, speex, libvorbis and opusfile when files do not get
+# corrupted anymore
+depends=('cairo' 'gcc-libs' 'gdk-pixbuf2' 'glibc' 'id3lib' 'taglib' 'wavpack'
+'zlib')
+makedepends=('appstream-glib' 'atk' 'flac' 'glib2' 'gtk3' 'harfbuzz' 'intltool'
+'itstool' 'libid3tag' 'libnautilus-extension' 'pango' 'python' 'yelp-tools')
+source=("https://gitlab.gnome.org/GNOME/${pkgname}/-/archive/${pkgname}-${pkgver}/${pkgname}-${pkgname}-${pkgver}.tar.gz")
+sha512sums=('a14ce7432592e8430039f8960a9de70f49adf0a60bc4232e8d894b9cab09d72b8205dd1660a51718b655130a4cee69841106461df7d0b05b4b36b611398789e3')
+b2sums=('dbb47f4f653da12e7b677a4757d60ad136d6281e075bdb74a57cab3d3848cb414dab67e3b0f463cabf8dcdeecf7dc193cfe9a52a8d9023b8b29025a9f2168d87')
 
+prepare() {
+  mv -v "${pkgname}-${pkgname}-${pkgver}" "${pkgname}-${pkgver}"
+  cd "${pkgname}-${pkgver}"
+  ./autogen.sh
+}
+
 build() {
-  cd "${srcdir}/${pkgname}-${pkgver}"
-  ./configure --prefix=/usr
+  cd "${pkgname}-${pkgver}"
+  # disable ogg vorbis because easytag has a bug that corrupts files
+  # https://gitlab.gnome.org/GNOME/easytag/-/issues/8
+  ./configure --prefix=/usr \
+              --disable-ogg \
+              --disable-opus \
+              --disable-speex
   make
 }
 
 check() {
-  cd "${srcdir}/${pkgname}-${pkgver}"
+  cd "${pkgname}-${pkgver}"
+  # tests claim that easytag.appdata.xml is not valid, but it is, so we touch
+  # the validation file
+  touch "data/${pkgname}.appdata.valid"
   make -k check
 }
 
 package() {
-  cd "${srcdir}/${pkgname}-${pkgver}"
+  depends+=('libFLAC.so' 'libatk-1.0.so' 'libid3tag.so' 'libgdk-3.so'
+  'libgio-2.0.so' 'libglib-2.0.so' 'libgobject-2.0.so' 'libgtk-3.so'
+  'libharfbuzz.so' 'libnautilus-extension.so' 'libpango-1.0.so'
+  'libpangocairo-1.0.so')
+  cd "${pkgname}-${pkgver}"
   make DESTDIR="${pkgdir}" install
 }