[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, September 8, 2020 @ 22:25:02
  Author: felixonmars
Revision: 701394

addpkg: haskell-lsp-types 0.22.0.0-1

Added:
  haskell-lsp-types/
  haskell-lsp-types/repos/
  haskell-lsp-types/trunk/
  haskell-lsp-types/trunk/PKGBUILD

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Added: haskell-lsp-types/trunk/PKGBUILD
===================================================================
--- haskell-lsp-types/trunk/PKGBUILD	                        (rev 0)
+++ haskell-lsp-types/trunk/PKGBUILD	2020-09-08 22:25:02 UTC (rev 701394)
@@ -0,0 +1,41 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=haskell-lsp-types
+pkgname=haskell-lsp-types
+pkgver=0.22.0.0
+pkgrel=1
+pkgdesc="Haskell library for the Microsoft Language Server Protocol, data types"
+url="https://github.com/alanz/haskell-lsp"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-data-default' 'haskell-hashable' 'haskell-lens'
+         'haskell-network-uri' 'haskell-scientific' 'haskell-unordered-containers')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('756a78674b023d19d5a900bddb1c9464b4ff8fb68aa2804181ba4e9e4b2b8714')
+
+build() {
+  cd $_hkgname-$pkgver    
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}