[arch-commits] Commit in haskell-hspec-core/repos (2 files)

Felix Yan felixonmars at archlinux.org
Wed Sep 9 10:38:50 UTC 2020


    Date: Wednesday, September 9, 2020 @ 10:38:50
  Author: felixonmars
Revision: 701525

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hspec-core/repos/community-staging-x86_64/
  haskell-hspec-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 701524, haskell-hspec-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-hspec-core/repos/community-staging-x86_64/PKGBUILD (from rev 701524, haskell-hspec-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-09-09 10:38:50 UTC (rev 701525)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hspec-core
+pkgname=haskell-hspec-core
+pkgver=2.7.3
+pkgrel=7
+pkgdesc="A Testing Framework for Haskell"
+url="http://hspec.github.io/"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-call-stack' 'haskell-clock'
+         'haskell-hspec-expectations' 'haskell-hunit' 'haskell-quickcheck' 'haskell-quickcheck-io'
+         'haskell-random' 'haskell-setenv' 'haskell-tf-random')
+makedepends=('ghc' 'haskell-hspec-meta' 'haskell-silently' 'haskell-temporary')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('8a71bca8985a9a75463e4ce41f565325dcec0e2948ebb52b7b041b3796fa06d3fceb46e2108201c9de7c6eeba4ae258303a512bbbf4e1b858e8de983023bbce5')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # https://github.com/hspec/hspec/issues/432
+    runhaskell Setup test || :
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}


More information about the arch-commits mailing list