[arch-commits] Commit in qt5-webkit/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Antonio Rojas arojas at archlinux.org
Wed Sep 9 11:17:58 UTC 2020


    Date: Wednesday, September 9, 2020 @ 11:17:56
  Author: arojas
Revision: 395640

archrelease: copy trunk to staging-x86_64

Added:
  qt5-webkit/repos/staging-x86_64/
  qt5-webkit/repos/staging-x86_64/PKGBUILD
    (from rev 395639, qt5-webkit/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: qt5-webkit/repos/staging-x86_64/PKGBUILD (from rev 395639, qt5-webkit/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-09-09 11:17:56 UTC (rev 395640)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=qt5-webkit
+_pkgver=5.212.0-alpha4
+pkgver=${_pkgver/-/}
+pkgrel=7
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='Classes for a WebKit2 based implementation and a new QML API'
+source=("https://github.com/qtwebkit/qtwebkit/releases/download/qtwebkit-$_pkgver/qtwebkit-$_pkgver.tar.xz")
+depends=(qt5-location qt5-sensors qt5-webchannel libwebp libxslt libxcomposite gst-plugins-base hyphen woff2)
+makedepends=(cmake ruby gperf python qt5-doc qt5-tools)
+optdepends=('gst-plugins-good: Webm codec support')
+sha256sums=('9ca126da9273664dd23a3ccd0c9bebceb7bb534bddd743db31caf6a5a6d4a9e6')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+
+  cmake ../qtwebkit-$_pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG" \
+    -DPORT=Qt \
+    -DENABLE_TOOLS=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
+}


More information about the arch-commits mailing list