[arch-commits] Commit in fping/repos (3 files)

[Christian Hesse]

    Date: Wednesday, September 9, 2020 @ 21:43:31
  Author: eworm
Revision: 395667

archrelease: copy trunk to testing-x86_64

Added:
  fping/repos/testing-x86_64/
  fping/repos/testing-x86_64/PKGBUILD
    (from rev 395666, fping/trunk/PKGBUILD)
  fping/repos/testing-x86_64/fping.install
    (from rev 395666, fping/trunk/fping.install)

---------------+
 PKGBUILD      |   38 ++++++++++++++++++++++++++++++++++++++
 fping.install |    9 +++++++++
 2 files changed, 47 insertions(+)

Copied: fping/repos/testing-x86_64/PKGBUILD (from rev 395666, fping/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-09-09 21:43:31 UTC (rev 395667)
@@ -0,0 +1,38 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Tom Newsom <Jeepster at gmx.co.uk>
+
+pkgname=fping
+pkgver=5.0
+pkgrel=1
+pkgdesc='Utility to ping multiple hosts at once'
+url='https://www.fping.org/'
+arch=('x86_64')
+license=('custom')
+depends=('glibc')
+install=${pkgname}.install
+source=(https://www.fping.org/dist/${pkgname}-${pkgver}.tar.gz{,.asc})
+sha512sums=('c843f7bb7c4e3289c4dd9eb8ae2ab93a363316c0000aac9187f79580a3d2505df179f2e0ae9e0a791c74bfc9e17c476874f8e122dfa6ad74930498c4e02d0de3'
+            'SKIP')
+b2sums=('6dbb6708ecb55c1f1281bcd9e298475a1ad3a21aa81d8488b61cb39ad07d1d7285247a3c39883cbaae0b1a0e4403b6340ea7ec43411b81546f0e8eeefb02ef88'
+        'SKIP')
+validpgpkeys=('8D1E89B8FBA920A5A609F2615A11A22BC5A1F734') # David Schweikert <david at schweikert.ch>
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --mandir=/usr/share/man \
+    --enable-ipv4 \
+    --enable-ipv6
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:

Copied: fping/repos/testing-x86_64/fping.install (from rev 395666, fping/trunk/fping.install)
===================================================================
--- testing-x86_64/fping.install	                        (rev 0)
+++ testing-x86_64/fping.install	2020-09-09 21:43:31 UTC (rev 395667)
@@ -0,0 +1,9 @@
+post_install() {
+  setcap cap_net_raw=ep usr/bin/fping  2>/dev/null || chmod +s usr/bin/fping
+}
+
+post_upgrade() {
+  post_install "$1"
+}
+
+# vim:set ts=2 sw=2 et: