[arch-commits] Commit in radare2-cutter/repos (2 files)

Antonio Rojas arojas at archlinux.org
Thu Sep 10 17:22:18 UTC 2020


    Date: Thursday, September 10, 2020 @ 17:22:18
  Author: arojas
Revision: 702036

archrelease: copy trunk to community-testing-x86_64

Added:
  radare2-cutter/repos/community-testing-x86_64/
  radare2-cutter/repos/community-testing-x86_64/PKGBUILD
    (from rev 702035, radare2-cutter/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: radare2-cutter/repos/community-testing-x86_64/PKGBUILD (from rev 702035, radare2-cutter/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-09-10 17:22:18 UTC (rev 702036)
@@ -0,0 +1,50 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Santiago Torres-Arias <santiago[at]archlinux[dot]org>
+# Contributor: Aaron McDaniel (mcd1992) <'aur' at the domain 'fgthou.se'>
+
+pkgname=radare2-cutter
+_gitcommit=9a822ec3964381cb917da593b6404ee72be5433a
+pkgver=1.11.1
+epoch=1
+pkgrel=2
+pkgdesc='Qt and C++ GUI for radare2 reverse engineering framework'
+url='https://github.com/radareorg/cutter'
+arch=('x86_64')
+license=('GPL3')
+depends=('radare2' 'capstone' 'qt5-base' 'qt5-svg' 'qt5-webengine' 'icu' 'python' 'jupyter'
+         'pyside2' 'python-shiboken2' 'graphviz' 'gcc-libs')
+makedepends=('git' 'cmake' 'shiboken2' 'qt5-tools')
+optdepends=('r2ghidra-dec: ghidra decompiler plugin')
+source=(${pkgname}::"git+https://github.com/radareorg/cutter#commit=${_gitcommit}")
+sha512sums=('SKIP')
+b2sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname}
+  git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd ${pkgname}/src
+  cmake -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCUTTER_ENABLE_PYTHON=ON \
+    -DCUTTER_ENABLE_PYTHON_BINDINGS=ON \
+    -DCUTTER_USE_BUNDLED_RADARE2=OFF \
+    -DCUTTER_USE_ADDITIONAL_RADARE2_PATHS=OFF \
+    -DCUTTER_ENABLE_CRASH_REPORTS=OFF \
+    -DCUTTER_ENABLE_GRAPHVIZ=ON
+  make -C build VERBOSE=1
+}
+
+package() {
+  cd ${pkgname}
+  install -Dm 755 src/build/Cutter -t "${pkgdir}/usr/bin"
+  install -Dm 644 src/org.radare.Cutter.desktop -t "${pkgdir}/usr/share/applications"
+  install -Dm 644 src/img/cutter.svg -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps"
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -a docs/* "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list