[arch-commits] Commit in gst-plugins-base/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 12, 2020 @ 01:17:24
  Author: heftig
Revision: 395804

archrelease: copy trunk to testing-x86_64

Added:
  gst-plugins-base/repos/testing-x86_64/
  gst-plugins-base/repos/testing-x86_64/PKGBUILD
    (from rev 395801, gst-plugins-base/trunk/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: gst-plugins-base/repos/testing-x86_64/PKGBUILD (from rev 395801, gst-plugins-base/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2020-09-12 01:17:24 UTC (rev 395804)
@@ -0,0 +1,66 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gst-plugins-base
+pkgname=(gst-plugins-base-libs gst-plugins-base)
+pkgver=1.18.0
+pkgrel=1
+pkgdesc="Multimedia graph framework - base plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gstreamer orc libxv iso-codes libgudev mesa)
+makedepends=(alsa-lib cdparanoia libvisual libvorbis libtheora pango opus
+             graphene libpng libjpeg gobject-introspection git meson
+             gtk3 qt5-{base,tools,x11extras} clutter sdl2 glu)
+checkdepends=(xorg-server-xvfb)
+options=(!emptydirs)
+_commit=f21623c1f60949ed6a77e2c2c3857be942cd2db5  # tags/1.18.0^0
+source=("git+https://gitlab.freedesktop.org/gstreamer/gst-plugins-base.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+
+build() {
+  arch-meson $pkgbase build \
+    -D doc=disabled \
+    -D tremor=disabled \
+    -D gobject-cast-checks=disabled \
+    -D package-name="GStreamer Base Plugins (Arch Linux)" \
+    -D package-origin="https://www.archlinux.org/"
+  meson compile -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  export XDG_RUNTIME_DIR
+
+  xvfb-run -s '-screen 0 1920x1080x24 -nolisten local +iglx -noreset' \
+    meson test -C build --print-errorlogs
+)
+
+package_gst-plugins-base-libs() {
+  pkgdesc="${pkgdesc% plugins}"
+
+  DESTDIR="$pkgdir" meson install -C build
+
+  mkdir -p ext/lib/gstreamer-1.0
+  for _x in alsa cdparanoia libvisual ogg opengl opus pango theora vorbis; do
+    _x="lib/gstreamer-1.0/libgst${_x}.so"
+    mv "$pkgdir/usr/$_x" "ext/$_x"
+  done
+}
+
+package_gst-plugins-base() {
+  depends=("gst-plugins-base-libs=$pkgver"
+           alsa-lib cdparanoia libvisual libvorbis libtheora pango opus graphene libpng libjpeg)
+
+  mv ext "$pkgdir/usr"
+}