[arch-commits] Commit in (4 files)
Felix Yan
felixonmars at archlinux.org
Thu Sep 17 06:33:33 UTC 2020
Date: Thursday, September 17, 2020 @ 06:33:33
Author: felixonmars
Revision: 708555
addpkg: haskell-lsp 0.22.0.0-1
Added:
haskell-lsp/
haskell-lsp/repos/
haskell-lsp/trunk/
haskell-lsp/trunk/PKGBUILD
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Added: haskell-lsp/trunk/PKGBUILD
===================================================================
--- haskell-lsp/trunk/PKGBUILD (rev 0)
+++ haskell-lsp/trunk/PKGBUILD 2020-09-17 06:33:33 UTC (rev 708555)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=haskell-lsp
+pkgname=haskell-lsp
+pkgver=0.22.0.0
+pkgrel=1
+pkgdesc="Haskell library for the Microsoft Language Server Protocol"
+url="https://github.com/alanz/haskell-lsp"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-async' 'haskell-attoparsec' 'haskell-data-default'
+ 'haskell-hashable' 'haskell-lsp-types' 'haskell-hslogger' 'haskell-lens'
+ 'haskell-network-uri' 'haskell-rope-utf16-splay' 'haskell-sorted-list'
+ 'haskell-temporary' 'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-hspec' 'haskell-hspec-discover'
+ 'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('1c50119b905199ea58fd1992f935e96e8242eb861f9c713bbd6318f5db580256')
+
+build() {
+ cd $_hkgname-$pkgver
+
+ runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+ --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+ --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+ --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+ --ghc-option='-pie'
+
+ runhaskell Setup build
+ runhaskell Setup register --gen-script
+ runhaskell Setup unregister --gen-script
+ sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+ sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+ cd $_hkgname-$pkgver
+ runhaskell Setup test
+}
+
+package() {
+ cd $_hkgname-$pkgver
+
+ install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+ install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+ runhaskell Setup copy --destdir="$pkgdir"
+ install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+ rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}
More information about the arch-commits
mailing list