[arch-commits] Commit in plasma-desktop/repos (2 files)

Antonio Rojas arojas at archlinux.org
Thu Sep 17 17:11:00 UTC 2020


    Date: Thursday, September 17, 2020 @ 17:10:59
  Author: arojas
Revision: 396212

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  plasma-desktop/repos/kde-unstable-x86_64/
  plasma-desktop/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 396211, plasma-desktop/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: plasma-desktop/repos/kde-unstable-x86_64/PKGBUILD (from rev 396211, plasma-desktop/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2020-09-17 17:10:59 UTC (rev 396212)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=plasma-desktop
+pkgname=(plasma-desktop knetattach)
+pkgver=5.19.90
+pkgrel=1
+pkgdesc='KDE Plasma Desktop'
+arch=(x86_64)
+url='https://www.kde.org/workspaces/plasmadesktop/'
+license=(LGPL)
+source=("https://download.kde.org/unstable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
+depends=(polkit-kde-agent libxkbfile kmenuedit systemsettings ksysguard baloo libibus)
+makedepends=(extra-cmake-modules kdoctools xf86-input-evdev xf86-input-synaptics xf86-input-libinput xorg-server-devel
+             scim kdesignerplugin kaccounts-integration intltool)
+replaces=(user-manager)
+groups=(plasma)
+sha256sums=('b5b78212257b8d352b0c86a321dedba65fd05d85d5395ebec4e357331ade491e'
+            'SKIP')
+validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell <jr at jriddell.org>
+              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah at kde.org>
+              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson at kde.org>
+              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package_plasma-desktop() {
+  depends+=(knetattach)
+  optdepends=('plasma-nm: Network manager applet'
+              'powerdevil: power management, suspend and hibernate support'
+              'kscreen: screen management'
+              'ibus: kimpanel IBUS support'
+              'scim: kimpanel SCIM support'
+              'kaccounts-integration: OpenDesktop integration plugin')
+
+  DESTDIR="$pkgdir" cmake --install build
+
+# Split knetattach
+  rm "$pkgdir"/usr/{bin/knetattach,share/applications/org.kde.knetattach.desktop}
+}
+
+package_knetattach() {
+  pkgdesc='Wizard which makes it easier to integrate network resources with the Plasma Desktop'
+  depends=(kdelibs4support)
+
+  DESTDIR="$pkgdir" cmake --install build/knetattach
+}


More information about the arch-commits mailing list