[arch-commits] Commit in (eksctl eksctl/repos eksctl/trunk eksctl/trunk/PKGBUILD)

[Levente Polyak]

    Date: Friday, September 18, 2020 @ 20:41:18
  Author: anthraxx
Revision: 710747

addpkg: eksctl 0.27.0-2

Added:
  eksctl/
  eksctl/repos/
  eksctl/trunk/
  eksctl/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: eksctl/trunk/PKGBUILD
===================================================================
--- eksctl/trunk/PKGBUILD	                        (rev 0)
+++ eksctl/trunk/PKGBUILD	2020-09-18 20:41:18 UTC (rev 710747)
@@ -0,0 +1,42 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: David Birks <david at birks.dev>
+# Contributor: Mike Williamson <mike at korora dot ca>
+
+pkgname=eksctl
+pkgver=0.27.0
+pkgrel=2
+pkgdesc='Command line tool for creating clusters on Amazon EKS'
+url='https://github.com/weaveworks/eksctl'
+arch=('x86_64')
+license=('Apache')
+depends=('kubectl' 'glibc')
+makedepends=('go')
+source=("${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha256sums=('5c5b3f4a1b5570c74822e1de985232a6cda3dae46c87837b3e06bf80d429f7b8')
+b2sums=('f0d5e9bc112d508a67a8c6ca77a82f64b497b273ebcd8994f773665a93826893539c30107bf4d68441b051cc3f3e2e7c4cb0dce97abf1293d9178bacdcd28079')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-buildmode=pie -ldflags=-linkmode=external -trimpath -mod=readonly -modcacherw"
+  go build -v \
+    -ldflags "-linkmode=external -extldflags '${LDFLAGS}' -X github.com/weaveworks/eksctl/pkg/version.gitTag=${pkgver}" \
+    ./cmd/eksctl
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  install -Dm 755 ${pkgname} -t "$pkgdir/usr/bin"
+
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+
+  # completions
+  "${pkgdir}/usr/bin/${pkgname}" completion bash | install -Dm 644 /dev/stdin "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
+  "${pkgdir}/usr/bin/${pkgname}" completion zsh | install -Dm 644 /dev/stdin "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
+  "${pkgdir}/usr/bin/${pkgname}" completion fish | install -Dm 644 /dev/stdin "${pkgdir}/usr/share/fish/completions/${pkgname}.fish"
+}
+
+# vim: ts=2 sw=2 et: