[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, September 20, 2020 @ 13:27:16
  Author: felixonmars
Revision: 711091

addpkg: haskell-universe-base 1.1.1-1

Added:
  haskell-universe-base/
  haskell-universe-base/repos/
  haskell-universe-base/trunk/
  haskell-universe-base/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: haskell-universe-base/trunk/PKGBUILD
===================================================================
--- haskell-universe-base/trunk/PKGBUILD	                        (rev 0)
+++ haskell-universe-base/trunk/PKGBUILD	2020-09-20 13:27:16 UTC (rev 711091)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=universe-base
+pkgname=haskell-universe-base
+pkgver=1.1.1
+pkgrel=1
+pkgdesc="A class for finite and recursively enumerable types."
+url="https://github.com/dmwit/universe"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-tagged')
+makedepends=('ghc' 'arch-hs' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('1ded30b31b1abbc7621bdb0086ba0d91c1920157e87a4abeb4f2fcf9f3f6dea8')
+
+prepare() {
+  arch-hs-uusi $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}