[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, September 20, 2020 @ 17:36:03
  Author: felixonmars
Revision: 711118

addpkg: haskell-ci 0.10.3-1

Added:
  haskell-ci/
  haskell-ci/repos/
  haskell-ci/trunk/
  haskell-ci/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: haskell-ci/trunk/PKGBUILD
===================================================================
--- haskell-ci/trunk/PKGBUILD	                        (rev 0)
+++ haskell-ci/trunk/PKGBUILD	2020-09-20 17:36:03 UTC (rev 711118)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=haskell-ci
+pkgname=haskell-ci
+pkgver=0.10.3
+pkgrel=1
+pkgdesc="Cabal package script generator for Travis-CI"
+url="https://haskell-ci.rtfd.org/"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-base-compat' 'haskell-cabal-install-parsers'
+         'haskell-generic-lens-lite' 'haskell-hsyaml' 'haskell-lattices' 'haskell-network-uri'
+         'haskell-optparse-applicative' 'haskell-temporary' 'haskell-unordered-containers'
+         'shellcheck')
+makedepends=('ghc' 'arch-hs' 'haskell-diff' 'haskell-ansi-terminal' 'haskell-tasty' 'haskell-tasty-golden')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('7b8bd970619344c8254a678038a19f838a5b4eaba39a8d42c640aa50e1b31ea3')
+
+prepare(){
+  arch-hs-uusi $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver    
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}