[arch-commits] Commit in python-lark-parser/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Mon Sep 21 09:07:53 UTC 2020
Date: Monday, September 21, 2020 @ 09:07:53
Author: felixonmars
Revision: 711151
archrelease: copy trunk to community-testing-any
Added:
python-lark-parser/repos/community-testing-any/
python-lark-parser/repos/community-testing-any/PKGBUILD
(from rev 711150, python-lark-parser/trunk/PKGBUILD)
----------+
PKGBUILD | 39 +++++++++++++++++++++++++++++++++++++++
1 file changed, 39 insertions(+)
Copied: python-lark-parser/repos/community-testing-any/PKGBUILD (from rev 711150, python-lark-parser/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD (rev 0)
+++ community-testing-any/PKGBUILD 2020-09-21 09:07:53 UTC (rev 711151)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=python-lark-parser
+pkgver=0.10.0
+_nearley_commit=a46b37471db486db0f6e1ce6a2934fb238346b44
+pkgrel=1
+pkgdesc="A modern parsing library"
+url="https://github.com/lark-parser/lark"
+license=('MIT')
+arch=('any')
+depends=('python')
+makedepends=('python-setuptools')
+checkdepends=('python-js2py')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/lark-parser/lark/archive/$pkgver.tar.gz"
+ "nearley-$_nearley_commit.tar.gz::https://github.com/kach/nearley/archive/$_nearley_commit.tar.gz")
+sha512sums=('b99a568c3fa79eb5afb5ec15a1b11a9f3f2e81821473f6e325f34db0c7ece88391c2015c51bb5774b30f306b55ed86f8809055280e857344d17f69728a7869bc'
+ 'fe14909f8a1d1626f8a632e8d48bf83602923f468b7bbb819557b85ab5e384cb042241ba15525e9850f2bbd65cad12497ed0b7ff6bc86c04d78b63d0c1bb66b4')
+
+prepare() {
+ rmdir lark-$pkgver/tests/test_nearley/nearley
+ ln -s "$srcdir"/nearley-$_nearley_commit lark-$pkgver/tests/test_nearley/nearley
+}
+
+build() {
+ cd lark-$pkgver
+ python setup.py build
+}
+
+check() {
+ cd lark-$pkgver
+ python -m tests
+}
+
+package() {
+ cd lark-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1
+
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
More information about the arch-commits
mailing list