[arch-commits] Commit in vala/repos (2 files)
Jan Steffens
heftig at archlinux.org
Mon Sep 21 18:45:52 UTC 2020
Date: Monday, September 21, 2020 @ 18:45:51
Author: heftig
Revision: 396406
archrelease: copy trunk to gnome-unstable-x86_64
Added:
vala/repos/gnome-unstable-x86_64/
vala/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 396405, vala/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: vala/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396405, vala/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2020-09-21 18:45:51 UTC (rev 396406)
@@ -0,0 +1,50 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Timm Preetz <timm at preetz.us>
+
+pkgname=vala
+pkgver=0.50.0
+pkgrel=1
+pkgdesc='Compiler for the GObject type system'
+url='https://wiki.gnome.org/Projects/Vala'
+arch=(x86_64)
+license=(LGPL)
+depends=(glib2 gtk-doc graphviz ttf-font pkg-config gcc)
+makedepends=(libxslt vala git help2man autoconf-archive)
+checkdepends=(dbus libx11 gobject-introspection)
+provides=(valadoc libvala-${pkgver%.*}.so libvaladoc-${pkgver%.*}.so)
+conflicts=(valadoc)
+replaces=(valadoc)
+_commit=b32985eaa47e78e840ae03be2f5ede3692eabd4f # tags/0.50.0^0
+source=("git+https://gitlab.gnome.org/GNOME/vala.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+ cd $pkgname
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+check() {
+ cd $pkgname
+ make check
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list