[arch-commits] Commit in swi-prolog/repos (2 files)
Alexander Rødseth
arodseth at archlinux.org
Wed Sep 23 13:51:37 UTC 2020
Date: Wednesday, September 23, 2020 @ 13:51:37
Author: arodseth
Revision: 711506
archrelease: copy trunk to community-testing-x86_64
Added:
swi-prolog/repos/community-testing-x86_64/
swi-prolog/repos/community-testing-x86_64/PKGBUILD
(from rev 711505, swi-prolog/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: swi-prolog/repos/community-testing-x86_64/PKGBUILD (from rev 711505, swi-prolog/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2020-09-23 13:51:37 UTC (rev 711506)
@@ -0,0 +1,50 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Jachym Barvinek <jachymb at gmail.com>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: John Proctor <jproctor at prium.net>
+# Contributor: Juergen Hoetzel <juergen at archlinux.org>
+
+pkgname=swi-prolog
+pkgver=8.2.1
+pkgrel=2
+pkgdesc='Prolog environment'
+arch=(x86_64)
+url='https://www.swi-prolog.org/'
+license=(GPL LGPL)
+depends=(libarchive libxcrypt libyaml qt5-base)
+makedepends=(cmake jdk-openjdk junit libjpeg libxft libxinerama libxpm ninja unixodbc)
+optdepends=('libjpeg: for using the pl2xpce library'
+ 'libxpm: for using the pl2xpce library'
+ 'libxinerama: for using the pl2xpce library'
+ 'libxft: for using the pl2xpce library'
+ 'jdk-openjdk: for using Prolog from Java'
+ 'java-runtime: for using Prolog from Java'
+ 'unixodbc: for using the odbc4pl library')
+source=("https://www.swi-prolog.org/download/stable/src/swipl-$pkgver.tar.gz")
+sha256sums=('331bc5093d72af0c9f18fc9ed83b88ef9ddec0c8d379e6c49fa43739c8bda2fb')
+
+build() {
+ mkdir -p build
+ cd build
+ cmake "$srcdir/swipl-$pkgver" \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_C_FLAGS="$CFLAGS -fPIC -ffile-prefix-map=$PWD= -w" \
+ -DLIBEDIT_LIBRARIES=/usr/lib/libedit.so.0 \
+ -DLIBEDIT_INCLUDE_DIR=/usr/include \
+ -G Ninja
+ "$srcdir/swipl-$pkgver/scripts/pgo-compile.sh"
+ ninja
+}
+
+check() {
+ # the prolog_in_java test fails
+ cd build && ctest -j 8 || true
+}
+
+package() {
+ DESTDIR="$pkgdir" ninja -C build install
+}
+
+# getver: www.swi-prolog.org/download/stable
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list