[arch-commits] Commit in taskell/repos (2 files)

[Felix Yan]

    Date: Thursday, September 24, 2020 @ 14:03:34
  Author: felixonmars
Revision: 711774

archrelease: copy trunk to community-staging-x86_64

Added:
  taskell/repos/community-staging-x86_64/
  taskell/repos/community-staging-x86_64/PKGBUILD
    (from rev 711773, taskell/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: taskell/repos/community-staging-x86_64/PKGBUILD (from rev 711773, taskell/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-09-24 14:03:34 UTC (rev 711774)
@@ -0,0 +1,48 @@
+# Maintainer: Jelle van der Waa <jelle at archlinux.org
+
+pkgname=taskell
+pkgver=1.10.0
+pkgrel=2
+pkgdesc='A command-line kanban board/task manager'
+license=(BSD)
+arch=(x86_64)
+url="https://hackage.haskell.org/package/$pkgname"
+depends=(ghc-libs haskell-aeson haskell-attoparsec haskell-brick haskell-config-ini haskell-file-embed haskell-fold-debounce haskell-http-client haskell-http-conduit haskell-http-types haskell-lens haskell-tz haskell-vty haskell-classy-prelude)
+makedepends=(ghc uusi haskell-classy-prelude haskell-raw-strings-qq haskell-tasty haskell-tasty-discover haskell-tasty-expected-failure haskell-tasty-hunit)
+source=(https://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz)
+sha512sums=('08806885b3ad70606423e3189fa4f3c2f3586db7b0be496aeef796ba5f40eeb1e2eb2e0a175b3e1bdd98d33bad34d61621db2dabe8485bd4a2c54f13c9f441b0')
+
+prepare() {
+  uusi $pkgname-$pkgver/$pkgname.cabal
+}
+
+build() {
+  cd $pkgname-$pkgver
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --datasubdir=$pkgname \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $pkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $pkgname-$pkgver
+  runghc Setup.hs copy --destdir="$pkgdir"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+  # Doc only contains the license
+  rm -rf "$pkgdir/usr/share/doc"
+}
+
+# vim: ts=2 sw=2 et: