[arch-commits] Commit in vlc/repos (4 files)

Levente Polyak anthraxx at archlinux.org
Thu Sep 24 21:45:13 UTC 2020


    Date: Thursday, September 24, 2020 @ 21:45:12
  Author: anthraxx
Revision: 396502

archrelease: copy trunk to staging-x86_64

Added:
  vlc/repos/staging-x86_64/
  vlc/repos/staging-x86_64/PKGBUILD
    (from rev 396501, vlc/trunk/PKGBUILD)
  vlc/repos/staging-x86_64/qt_5_15.patch
    (from rev 396501, vlc/trunk/qt_5_15.patch)
  vlc/repos/staging-x86_64/update-vlc-plugin-cache.hook
    (from rev 396501, vlc/trunk/update-vlc-plugin-cache.hook)

------------------------------+
 PKGBUILD                     |  245 +++++++++++++++++++++++++++++++++++++++++
 qt_5_15.patch                |   33 +++++
 update-vlc-plugin-cache.hook |   11 +
 3 files changed, 289 insertions(+)

Copied: vlc/repos/staging-x86_64/PKGBUILD (from rev 396501, vlc/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-09-24 21:45:12 UTC (rev 396502)
@@ -0,0 +1,245 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Sarah Hay <sarahhay at mb.sympatico.ca>
+# Contributor: Martin Sandsmark <martin.sandsmark at kde.org>
+
+pkgname=vlc
+_vlcver=3.0.11.1
+# optional fixup version including hyphen
+_vlcfixupver=
+pkgver=${_vlcver}${_vlcfixupver//-/.r}
+pkgrel=3
+pkgdesc='Multi-platform MPEG, VCD/DVD, and DivX player'
+url='https://www.videolan.org/vlc/'
+arch=('x86_64')
+license=('LGPL2.1' 'GPL2')
+depends=('a52dec' 'libdvbpsi' 'libxpm' 'libdca' 'libproxy' 'lua52' 'libidn'
+         'libmatroska' 'taglib' 'libmpcdec' 'ffmpeg' 'faad2' 'libupnp' 'libmad'
+         'libmpeg2' 'xcb-util-keysyms' 'libtar' 'libxinerama' 'libsecret'
+         'libarchive' 'qt5-base' 'qt5-x11extras' 'qt5-svg' 'freetype2'
+         'fribidi' 'harfbuzz' 'fontconfig' 'libxml2' 'gnutls' 'libplacebo'
+         'wayland-protocols' 'aribb24')
+makedepends=('gst-plugins-base-libs' 'live-media' 'libnotify' 'libbluray'
+             'flac' 'libdc1394' 'libavc1394' 'libcaca' 'gtk3'
+             'librsvg' 'libgme' 'xosd' 'twolame' 'aalib' 'avahi' 'systemd-libs'
+             'libmtp' 'libupnp' 'libmicrodns' 'libdvdcss' 'smbclient'
+             'vcdimager' 'libssh2' 'mesa' 'protobuf' 'libnfs' 'mpg123'
+             'libdvdread' 'libdvdnav' 'libogg' 'libshout' 'libmodplug' 'libvpx'
+             'libvorbis' 'speex' 'opus' 'libtheora' 'libpng' 'libjpeg-turbo'
+             'libx265.so' 'libx264.so' 'zvbi' 'libass' 'libkate' 'libtiger'
+             'sdl_image' 'libpulse' 'alsa-lib' 'jack' 'libsamplerate' 'libsoxr'
+             'lirc' 'libgoom2' 'projectm' 'chromaprint' 'aom' 'srt' 'dav1d')
+optdepends=('avahi: service discovery using bonjour protocol'
+            'aom: AOM AV1 codec'
+            'gst-plugins-base-libs: for libgst plugins'
+            'dav1d: dav1d AV1 decoder'
+            'libdvdcss: decoding encrypted DVDs'
+            'libavc1394: devices using the 1394ta AV/C'
+            'libdc1394: IEEE 1394 access plugin'
+            'kwallet: kwallet keystore'
+            'libva-vdpau-driver: vdpau backend nvidia'
+            'libva-intel-driver: video backend intel'
+            'libbluray: Blu-Ray video input'
+            'flac: Free Lossless Audio Codec plugin'
+            'twolame: TwoLAME mpeg2 encoder plugin'
+            'libgme: Game Music Emu plugin'
+            'vcdimager: navigate VCD with libvcdinfo'
+            'libmtp: MTP devices discovery'
+            'systemd-libs: udev services discovery'
+            'smbclient: SMB access plugin'
+            'libcdio: audio CD playback'
+            'gnu-free-fonts: subtitle font '
+            'ttf-dejavu: subtitle font'
+            'libssh2: sftp access'
+            'libnfs: NFS access'
+            'mpg123: mpg123 codec'
+            'protobuf: chromecast streaming'
+            'libmicrodns: mDNS services discovery (chromecast etc)'
+            'lua52-socket: http interface'
+            'live-media: RTSP input'
+            'libdvdread: DVD input module'
+            'libdvdnav: DVD with navigation input module'
+            'libogg: Ogg and OggSpots codec'
+            'libshout: shoutcast/icecast output plugin'
+            'libmodplug: MOD output plugin'
+            'libvpx: VP8 and VP9 codec'
+            'libvorbis: Vorbis decoder/encoder'
+            'speex: Speex codec'
+            'opus: opus codec'
+            'libtheora: theora codec'
+            'libpng: PNG support'
+            'libjpeg-turbo: JPEG support'
+            'librsvg: SVG plugin'
+            'x264: H264 encoding'
+            'x265: HEVC/H.265 encoder'
+            'zvbi: VBI/Teletext/webcam/v4l2 capture/decoding'
+            'libass: Subtitle support'
+            'libkate: Kate codec'
+            'libtiger: Tiger rendering for Kate streams'
+            'sdl_image: SDL image support'
+            'srt: SRT input/output plugin'
+            'aalib: ASCII art video output'
+            'libcaca: colored ASCII art video output'
+            'libpulse: PulseAudio audio output'
+            'alsa-lib: ALSA audio output'
+            'jack: jack audio server'
+            'libsamplerate: audio Resampler'
+            'libsoxr: SoX audio Resampler'
+            'chromaprint: Chromaprint audio fingerprinter'
+            'lirc: lirc control'
+            'libgoom2: Goom visualization'
+            'projectm: ProjectM visualisation'
+            'ncurses: ncurses interface'
+            'libnotify: notification plugin'
+            'gtk3: notification plugin')
+conflicts=('vlc-plugin')
+replaces=('vlc-plugin')
+options=('!emptydirs')
+source=(https://download.videolan.org/${pkgname}/${_vlcver}/${pkgname}-${_vlcver}${_vlcfixupver}.tar.xz{,.asc}
+        update-vlc-plugin-cache.hook
+        qt_5_15.patch)
+sha512sums=('8ce1e2f11aabf847dc5c55cf21ce6d7c0419a1051b5f4795e36cd060eab82d5056e44b4c070b80af56744e6aa841ef538386d08bc3b397a444e7258b2ba3f76b'
+            'SKIP'
+            'b247510ffeadfd439a5dadd170c91900b6cdb05b5ca00d38b1a17c720ffe5a9f75a32e0cb1af5ebefdf1c23c5acc53513ed983a736e8fa30dd8fad237ef49dd3'
+            '43446257248461e7e6c237dbc63d58b994f4ce527573ff67437e3bade6ffb752aad94de19309c9cdca5f513e5c42f9d0c8b1db36198af6d41e18d3634c08761f')
+validpgpkeys=('65F7C6B4206BD057A7EB73787180713BE58D1ADC') # VideoLAN Release Signing Key
+
+prepare() {
+  cd ${pkgname}-${_vlcver}
+  sed -e 's:truetype/ttf-dejavu:TTF:g' -i modules/visualization/projectm.cpp
+  sed -e 's|-Werror-implicit-function-declaration||g' -i configure
+  sed 's|whoami|echo builduser|g' -i configure
+  sed 's|hostname -f|echo arch|g' -i configure
+  local src
+  for src in "${source[@]}"; do
+    src="${src%%::*}"
+    src="${src##*/}"
+    [[ $src = *.patch ]] || continue
+    msg2 "Applying patch $src..."
+    patch -Np1 < "../$src"
+  done
+}
+
+build() {
+  cd ${pkgname}-${_vlcver}
+
+  export CFLAGS+=" -I/usr/include/samba-4.0"
+  export CPPFLAGS+=" -I/usr/include/samba-4.0"
+  export CXXFLAGS+=" -std=c++11"
+  # upstream doesn't support lua 5.4 yet: https://trac.videolan.org/vlc/ticket/25036
+  export LUAC=/usr/bin/luac5.2
+  export LUA_LIBS="$(pkg-config --libs lua5.2)"
+  export RCC=/usr/bin/rcc-qt5
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --with-kde-solid=/usr/share/solid/actions/ \
+    --disable-rpath \
+    --enable-nls \
+    --enable-archive \
+    --enable-live555 \
+    --enable-dc1394 \
+    --enable-dv1394 \
+    --enable-dvdread \
+    --enable-dvdnav \
+    --enable-bluray \
+    --disable-opencv \
+    --enable-smbclient \
+    --enable-sftp \
+    --enable-nfs \
+    --enable-realrtsp \
+    --enable-dvbpsi \
+    --enable-gme \
+    --enable-ogg \
+    --enable-shout \
+    --enable-matroska \
+    --enable-mod \
+    --enable-mpc \
+    --enable-mad \
+    --enable-mpg123 \
+    --enable-gst-decode \
+    --enable-avcodec \
+    --enable-libva \
+    --enable-avformat \
+    --enable-postproc \
+    --enable-faad \
+    --enable-vpx \
+    --enable-twolame \
+    --disable-fdkaac \
+    --enable-a52 \
+    --enable-dca \
+    --enable-flac \
+    --enable-libmpeg2 \
+    --enable-vorbis \
+    --enable-speex \
+    --enable-opus \
+    --enable-oggspots \
+    --disable-schroedinger \
+    --enable-png \
+    --enable-jpeg \
+    --enable-x264 \
+    --enable-x265 \
+    --enable-zvbi \
+    --enable-libass \
+    --enable-kate \
+    --enable-tiger \
+    --enable-vdpau \
+    --enable-wayland \
+    --enable-sdl-image \
+    --enable-freetype \
+    --enable-fribidi \
+    --enable-harfbuzz \
+    --enable-fontconfig \
+    --enable-svg \
+    --enable-svgdec \
+    --enable-aa \
+    --enable-caca \
+    --enable-pulse \
+    --enable-alsa \
+    --enable-jack \
+    --enable-samplerate \
+    --enable-soxr \
+    --enable-chromaprint \
+    --enable-chromecast \
+    --enable-qt \
+    --enable-skins2 \
+    --enable-libtar \
+    --enable-ncurses \
+    --enable-lirc \
+    --enable-goom \
+    --enable-projectm \
+    --enable-avahi \
+    --enable-mtp \
+    --enable-upnp \
+    --enable-microdns \
+    --enable-libxml2 \
+    --disable-libgcrypt \
+    --enable-gnutls \
+    --enable-taglib \
+    --enable-secret \
+    --enable-kwallet \
+    --disable-update-check \
+    --enable-notify \
+    --enable-libplacebo \
+    --enable-vlc \
+    --enable-aribsub \
+    --enable-aom \
+    --enable-srt \
+    --enable-dav1d
+  make
+}
+
+package() {
+  cd ${pkgname}-${_vlcver}
+
+  make DESTDIR="${pkgdir}" install
+
+  for res in 16 32 48 128 256; do
+    install -Dm 644 "${srcdir}/vlc-${_vlcver}/share/icons/${res}x${res}/vlc.png" \
+                     "${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png"
+  done
+  install -Dm 644 "${srcdir}/update-vlc-plugin-cache.hook" -t "${pkgdir}/usr/share/libalpm/hooks"
+}
+
+# vim: ts=2 sw=2 et:

Copied: vlc/repos/staging-x86_64/qt_5_15.patch (from rev 396501, vlc/trunk/qt_5_15.patch)
===================================================================
--- staging-x86_64/qt_5_15.patch	                        (rev 0)
+++ staging-x86_64/qt_5_15.patch	2020-09-24 21:45:12 UTC (rev 396502)
@@ -0,0 +1,33 @@
+diff -u -r vlc-3.0.10/modules/gui/qt/components/playlist/views.cpp vlc-3.0.10-qt-5.15/modules/gui/qt/components/playlist/views.cpp
+--- vlc-3.0.10/modules/gui/qt/components/playlist/views.cpp	2017-11-24 15:29:17.000000000 +0000
++++ vlc-3.0.10-qt-5.15/modules/gui/qt/components/playlist/views.cpp	2020-05-29 20:50:09.267959371 +0000
+@@ -27,6 +27,7 @@
+ #include "input_manager.hpp"                      /* THEMIM */
+ 
+ #include <QPainter>
++#include <QPainterPath>
+ #include <QRect>
+ #include <QStyleOptionViewItem>
+ #include <QFontMetrics>
+diff -u -r vlc-3.0.10/modules/gui/qt/dialogs/plugins.cpp vlc-3.0.10-qt-5.15/modules/gui/qt/dialogs/plugins.cpp
+--- vlc-3.0.10/modules/gui/qt/dialogs/plugins.cpp	2017-11-24 15:29:17.000000000 +0000
++++ vlc-3.0.10-qt-5.15/modules/gui/qt/dialogs/plugins.cpp	2020-05-29 20:49:44.114275108 +0000
+@@ -53,6 +53,7 @@
+ #include <QListView>
+ #include <QListWidget>
+ #include <QPainter>
++#include <QPainterPath>
+ #include <QStyleOptionViewItem>
+ #include <QKeyEvent>
+ #include <QPushButton>
+diff -u -r vlc-3.0.10/modules/gui/qt/util/timetooltip.hpp vlc-3.0.10-qt-5.15/modules/gui/qt/util/timetooltip.hpp
+--- vlc-3.0.10/modules/gui/qt/util/timetooltip.hpp	2018-05-03 12:03:21.000000000 +0000
++++ vlc-3.0.10-qt-5.15/modules/gui/qt/util/timetooltip.hpp	2020-05-29 20:40:30.306628713 +0000
+@@ -24,6 +24,7 @@
+ 
+ #include "qt.hpp"
+ 
++#include <QPainterPath>
+ #include <QWidget>
+ 
+ class TimeTooltip : public QWidget

Copied: vlc/repos/staging-x86_64/update-vlc-plugin-cache.hook (from rev 396501, vlc/trunk/update-vlc-plugin-cache.hook)
===================================================================
--- staging-x86_64/update-vlc-plugin-cache.hook	                        (rev 0)
+++ staging-x86_64/update-vlc-plugin-cache.hook	2020-09-24 21:45:12 UTC (rev 396502)
@@ -0,0 +1,11 @@
+[Trigger]
+Type = Path
+Operation = Install
+Operation = Upgrade
+Operation = Remove
+Target = usr/lib/vlc/plugins/*
+
+[Action]
+Description = Updating the vlc plugin cache...
+When = PostTransaction
+Exec = /usr/lib/vlc/vlc-cache-gen /usr/lib/vlc/plugins


More information about the arch-commits mailing list