[arch-commits] Commit in libfido2/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Levente Polyak]

    Date: Thursday, September 24, 2020 @ 21:54:38
  Author: anthraxx
Revision: 396513

archrelease: copy trunk to staging-x86_64

Added:
  libfido2/repos/staging-x86_64/
  libfido2/repos/staging-x86_64/PKGBUILD
    (from rev 396512, libfido2/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: libfido2/repos/staging-x86_64/PKGBUILD (from rev 396512, libfido2/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-09-24 21:54:38 UTC (rev 396513)
@@ -0,0 +1,42 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Karol Babioch <karol at babioch.de>
+
+pkgname=libfido2
+pkgver=1.5.0
+pkgrel=2
+pkgdesc='Library functionality for FIDO 2.0, including communication with a device over USB'
+url='https://developers.yubico.com/libfido2/'
+arch=('x86_64')
+license=('BSD')
+depends=('glibc' 'openssl' 'libcbor' 'libcbor.so' 'hidapi' 'systemd-libs'  'libudev.so')
+makedepends=('cmake' 'systemd')
+provides=('libfido2.so')
+source=(https://developers.yubico.com/libfido2/Releases/libfido2-${pkgver}.tar.gz{,.sig})
+sha512sums=('240e2368e43846fddf5e98bbcc247468833565bcde4ec27976b88c814d787f1a477241a82b064818aa0eb0a98ff46a65d80b8243f4d0bbd763270e42492354e2'
+            'SKIP')
+b2sums=('23a04f9230c45652aa1ac9fd8b3e809096ae31699c65ca0fda27b27b1b47263e375bb99e5b1ebc515b9edfb801bb2fba9c4f50d88e755efe3eaa23463ca01946'
+        'SKIP')
+validpgpkeys=(
+  'EE90AE0D19774C8386628FAAB428949EF7914718' # pedro martelletto <pedro at yubico.com>
+  '1D7308B0055F5AEF36944A8F27A9C24D9588EA0F' # Aveen Ismail <aveen.ismail at yubico.com>
+  '7FBB6186957496D58C751AC20E777DD85755AA4A' # Konstantinos Georgantas <kostas at yubico.com>
+)
+
+build() {
+  cd ${pkgname}-${pkgver}
+  cmake -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_C_FLAGS="${CFLAGS} ${CPPFLAGS}"
+  make -C build VERBOSE=1
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm 644 NEWS README.adoc -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: