[arch-commits] Commit in jami-daemon/repos (2 files)

[Bruno Pagani]

    Date: Saturday, September 26, 2020 @ 00:02:01
  Author: archange
Revision: 712356

archrelease: copy trunk to community-staging-x86_64

Added:
  jami-daemon/repos/community-staging-x86_64/
  jami-daemon/repos/community-staging-x86_64/PKGBUILD
    (from rev 712355, jami-daemon/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: jami-daemon/repos/community-staging-x86_64/PKGBUILD (from rev 712355, jami-daemon/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-09-26 00:02:01 UTC (rev 712356)
@@ -0,0 +1,59 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Baptiste Jonglez <baptiste--aur at jonglez dot org>
+
+pkgname=jami-daemon
+pkgver=20200925
+pkgrel=1
+_pjprojectver=2.10
+pkgdesc="Free and universal communication platform which preserves the users’ privacy and freedoms (daemon component)"
+arch=(x86_64)
+url="https://jami.net"
+license=(GPL3)
+groups=(jami)
+depends=(opendht yaml-cpp alsa-lib libpulse jack jsoncpp dbus-c++ ffmpeg gnutls
+         expat libupnp libnatpmp libva libvdpau libsecp256k1 util-linux opus
+         openssl asio fmt http-parser libarchive)
+makedepends=(git boost msgpack-c restinio autoconf-archive)
+#checkdepends=(cppunit)
+_commit=b97ab28033a63673e99b2060fb3220a7d6f2ba33
+source=("git+https://git.jami.net/savoirfairelinux/ring-daemon.git#commit=${_commit}"
+        https://github.com/pjsip/pjproject/archive/${_pjprojectver}/pjproject-${_pjprojectver}.tar.gz)
+noextract=("pjproject-${_pjprojectver}.tar.gz")
+sha512sums=('SKIP'
+            'a67f083df175b536b4e6a7b7fe39e07d3ee805d6917ec64a50694542a7455c33a100889191044ab3fa679b6656774a6be045621aa53510b5f04cdde9ddd59893')
+
+prepare() {
+  cd ring-daemon
+  cp ../pjproject-${_pjprojectver}.tar.gz contrib/tarballs
+  mkdir contrib/native
+  autoreconf -fvi
+}
+
+build() {
+  cd ring-daemon/contrib/native
+  ../bootstrap \
+      --disable-downloads \
+      --disable-all \
+      --enable-pjproject
+  make DEPS_pjproject=
+
+  cd ../..
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --libexecdir=/usr/lib \
+    --sysconfdir=/etc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+# Disabled because some tests (TURN) use the network.
+#check() {
+#  cd ring-daemon
+#  make -k check
+#}
+
+package() {
+  cd ring-daemon
+  make DESTDIR="${pkgdir}" install
+}