[arch-commits] Commit in lib32-gamemode (3 files)

[Maxime Gauduin]

    Date: Saturday, September 26, 2020 @ 18:12:09
  Author: alucryd
Revision: 712500

archrelease: copy trunk to multilib-x86_64

Added:
  lib32-gamemode/repos/
  lib32-gamemode/repos/multilib-x86_64/
  lib32-gamemode/repos/multilib-x86_64/PKGBUILD
    (from rev 712499, lib32-gamemode/trunk/PKGBUILD)

----------+
 PKGBUILD |   61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

Copied: lib32-gamemode/repos/multilib-x86_64/PKGBUILD (from rev 712499, lib32-gamemode/trunk/PKGBUILD)
===================================================================
--- repos/multilib-x86_64/PKGBUILD	                        (rev 0)
+++ repos/multilib-x86_64/PKGBUILD	2020-09-26 18:12:09 UTC (rev 712500)
@@ -0,0 +1,61 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ysblokje <ysblokje at gmail.com>
+# Contributor: Mark Wagie <mark.wagie at tutanota.com>
+
+pkgname=lib32-gamemode
+pkgver=1.6
+pkgrel=9
+pkgdesc='A daemon/lib combo that allows games to request a set of optimisations be temporarily applied to the host OS'
+arch=(x86_64)
+url=https://github.com/FeralInteractive/gamemode
+license=(BSD)
+depends=(
+  lib32-dbus
+  lib32-glibc
+  lib32-systemd
+)
+makedepends=(
+  git
+  meson
+)
+checkdepends=(appstream)
+provides=(
+  libgamemode.so
+  libgamemodeauto.so
+)
+_tag=5f71f57db105c5d8682d5ab795651245603133ff
+source=(git+https://github.com/FeralInteractive/gamemode.git#tag=${_tag})
+b2sums=(SKIP)
+
+pkgver() {
+  cd gamemode
+
+  git describe --tags
+}
+
+build() {
+  export CC='gcc -m32'
+  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+
+  arch-meson gamemode build \
+    --libdir /usr/lib32 \
+    -Dwith-examples=false \
+    -Dwith-pam-group=gamemode \
+    -Dwith-sd-bus-provider=no-daemon \
+    -Dwith-systemd-user-unit-dir=/usr/lib/systemd/user \
+    -Dwith-util=false
+  meson compile -C build
+}
+
+check() {
+  meson test -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  rm -rf "${pkgdir}"/usr/include
+  install -dm 755 "${pkgdir}"/usr/share/licenses
+  ln -s gamemode "${pkgdir}"/usr/share/licenses/lib32-gamemode
+}
+
+# vim: set ts=4 sw=4 tw=0 et :