[arch-commits] Commit in gnome-desktop/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 26, 2020 @ 19:50:57
  Author: heftig
Revision: 396593

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-desktop/repos/gnome-unstable-x86_64/
  gnome-desktop/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 396592, gnome-desktop/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: gnome-desktop/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396592, gnome-desktop/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-09-26 19:50:57 UTC (rev 396593)
@@ -0,0 +1,46 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jan at archlinux.org>
+
+pkgname=gnome-desktop
+pkgver=3.38.0
+pkgrel=1
+epoch=1
+pkgdesc="Library with common API for various GNOME modules"
+url="https://gitlab.gnome.org/GNOME/gnome-desktop"
+arch=(x86_64)
+license=(GPL LGPL)
+depends=(gsettings-desktop-schemas gtk3 libxkbfile xkeyboard-config iso-codes
+         libseccomp bubblewrap systemd-libs)
+makedepends=(gobject-introspection git meson gtk-doc yelp-tools)
+checkdepends=(xorg-server-xvfb)
+provides=(libgnome-desktop-3.so)
+_commit=e4a843c97d87a4bd9780d0b2f031a97fc7516425  # tags/3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-desktop.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D gnome_distributor="Arch Linux" \
+    -D gtk_doc=true \
+    -D date_in_gnome_version=false
+  meson compile -C build
+}
+
+check() {
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local' \
+    meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}