[arch-commits] Commit in (5 files)

[Jan Steffens]

    Date: Saturday, September 26, 2020 @ 20:33:39
  Author: heftig
Revision: 396614

community2extra: Moving libhandy from community to extra

Added:
  libhandy/
  libhandy/repos/
  libhandy/trunk/
  libhandy/trunk/PKGBUILD
  libhandy/trunk/PKGBUILD.next

---------------+
 PKGBUILD      |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 PKGBUILD.next |   44 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)

Added: libhandy/trunk/PKGBUILD
===================================================================
--- libhandy/trunk/PKGBUILD	                        (rev 0)
+++ libhandy/trunk/PKGBUILD	2020-09-26 20:33:39 UTC (rev 396614)
@@ -0,0 +1,48 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=libhandy
+pkgver=0.0.13
+pkgrel=2
+pkgdesc="Library full of GTK+ widgets for mobile phones"
+arch=(x86_64)
+url="https://source.puri.sm/Librem5/libhandy"
+license=(LGPL2.1)
+depends=(glib2 gtk3)
+makedepends=(git glade gobject-introspection meson vala)
+checkdepends=(xorg-server-xvfb)
+provides=(libhandy-0.0.so)
+_commit=7a193d7692c9c76a1a94f17c4d30b585f77d177c  # tags/v0.0.13^0
+source=("git+https://source.puri.sm/Librem5/libhandy.git#commit=$_commit")
+sha256sums=('SKIP')
+
+prepare() {
+  cd $pkgname
+
+  # Fix build with glade 3.36.0
+  sed -e 's/GPC_OBJECT_DELIMITER/GLADE_PROPERTY_DEF_OBJECT_DELIMITER/g' \
+      -i glade/glade-*.c
+}
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D gtk_doc=true \
+    -D examples=false
+  meson compile -C build
+}
+
+check() {
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local' \
+    meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et:

Added: libhandy/trunk/PKGBUILD.next
===================================================================
--- libhandy/trunk/PKGBUILD.next	                        (rev 0)
+++ libhandy/trunk/PKGBUILD.next	2020-09-26 20:33:39 UTC (rev 396614)
@@ -0,0 +1,44 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=libhandy
+pkgver=0.80.0
+pkgrel=1
+pkgdesc="Library full of GTK+ widgets for mobile phones"
+arch=(x86_64)
+url="https://source.puri.sm/Librem5/libhandy"
+license=(LGPL2.1)
+depends=(glib2 gtk3)
+makedepends=(git glade gobject-introspection meson vala)
+checkdepends=(xorg-server-xvfb)
+provides=(libhandy-1.so)
+_commit=b61eefde06040703026f49a0b979588e69f77d3a  # tags/v0.80.0^0
+source=("git+https://source.puri.sm/Librem5/libhandy.git#commit=$_commit")
+sha256sums=('SKIP')
+
+prepare() {
+  cd $pkgname
+}
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D gtk_doc=true \
+    -D examples=false
+  meson compile -C build
+}
+
+check() {
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local' \
+    meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et: