[arch-commits] Commit in tracker3-miners/repos (2 files)
Jan Steffens
heftig at archlinux.org
Sun Sep 27 16:29:13 UTC 2020
Date: Sunday, September 27, 2020 @ 16:29:13
Author: heftig
Revision: 396729
archrelease: copy trunk to gnome-unstable-x86_64
Added:
tracker3-miners/repos/gnome-unstable-x86_64/
tracker3-miners/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 396728, tracker3-miners/trunk/PKGBUILD)
----------+
PKGBUILD | 43 +++++++++++++++++++++++++++++++++++++++++++
1 file changed, 43 insertions(+)
Copied: tracker3-miners/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396728, tracker3-miners/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2020-09-27 16:29:13 UTC (rev 396729)
@@ -0,0 +1,43 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=tracker3-miners
+pkgver=3.0.0
+pkgrel=1
+pkgdesc="Collection of data extractors for Tracker/Nepomuk"
+url="https://wiki.gnome.org/Projects/Tracker"
+arch=(x86_64)
+license=(GPL)
+depends=(tracker3 gst-plugins-base-libs exempi libexif libcue libgrss libgsf
+ libgxps libiptcdata libosinfo poppler-glib totem-plparser giflib
+ libgexiv2 gupnp-dlna upower libseccomp libnm)
+makedepends=(git meson vala asciidoc)
+checkdepends=(python-gobject gst-plugins-good gst-plugins-base gst-libav)
+groups=(gnome)
+_commit=cea59fcbed45faa31469cbc16be95456dbb3e9c4 # tags/3.0.0^0
+source=("git+https://gitlab.gnome.org/GNOME/tracker-miners.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd tracker-miners
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd tracker-miners
+}
+
+build() {
+ arch-meson tracker-miners build
+ meson compile -C build
+}
+
+check() {
+ # Intermittent test failures: https://gitlab.gnome.org/GNOME/tracker-miners/-/issues/79
+ dbus-run-session meson test -C build --print-errorlogs -t 3 || :
+}
+
+package() {
+ depends+=(libtracker-sparql-3.0.so)
+
+ DESTDIR="$pkgdir" meson install -C build
+}
More information about the arch-commits
mailing list