[arch-commits] Commit in tracker-miners/repos (2 files)

[Jan Steffens]

    Date: Sunday, September 27, 2020 @ 16:30:18
  Author: heftig
Revision: 396733

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  tracker-miners/repos/gnome-unstable-x86_64/
  tracker-miners/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 396732, tracker-miners/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: tracker-miners/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396732, tracker-miners/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-09-27 16:30:18 UTC (rev 396733)
@@ -0,0 +1,42 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=tracker-miners
+pkgver=2.3.5
+pkgrel=2
+pkgdesc="Collection of data extractors for Tracker/Nepomuk"
+url="https://wiki.gnome.org/Projects/Tracker"
+arch=(x86_64)
+license=(GPL)
+depends=(tracker gst-plugins-base-libs exempi flac libexif libcue libgrss libgsf libgxps libiptcdata
+         libosinfo libvorbis poppler-glib totem-plparser giflib libgexiv2 gupnp-dlna upower
+         libseccomp)
+makedepends=(intltool git meson vala)
+checkdepends=(python-gobject gst-plugins-good gst-plugins-base gst-libav)
+groups=(gnome)
+_commit=58fd82136d561e20adf71ab8a4ce02076ae7bf92  # tags/2.3.5^0
+source=("git+https://gitlab.gnome.org/GNOME/tracker-miners.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  # Intermittent test failures: https://gitlab.gnome.org/GNOME/tracker-miners/-/issues/79
+  dbus-run-session meson test -C build --print-errorlogs -t 3 || :
+}
+
+package() {
+  depends+=(libtracker-{miner,sparql}-2.0.so)
+  DESTDIR="$pkgdir" meson install -C build
+}