[arch-commits] Commit in nautilus/repos (2 files)
Jan Steffens
heftig at archlinux.org
Sun Sep 27 16:37:06 UTC 2020
Date: Sunday, September 27, 2020 @ 16:37:05
Author: heftig
Revision: 396740
archrelease: copy trunk to gnome-unstable-x86_64
Added:
nautilus/repos/gnome-unstable-x86_64/
nautilus/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 396739, nautilus/trunk/PKGBUILD)
----------+
PKGBUILD | 77 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 77 insertions(+)
Copied: nautilus/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396739, nautilus/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2020-09-27 16:37:05 UTC (rev 396740)
@@ -0,0 +1,77 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=nautilus
+pkgname=(nautilus libnautilus-extension)
+pkgver=3.38.0
+pkgrel=1
+pkgdesc="Default file manager for GNOME"
+url="https://wiki.gnome.org/Apps/Files"
+arch=(x86_64)
+license=(GPL)
+depends=(libgexiv2 gnome-desktop gvfs dconf tracker3 tracker3-miners
+ gnome-autoar gst-plugins-base-libs)
+makedepends=(gobject-introspection git gtk-doc meson appstream-glib)
+checkdepends=(python-gobject)
+_commit=5f1b9200cf648e1bbc0337180258394de7eff568 # tags/3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/nautilus.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+ 'SKIP')
+
+prepare() {
+ cd $pkgbase
+
+ git submodule init
+ git submodule set-url subprojects/libgd "$srcdir/libgd"
+ git submodule update
+}
+
+pkgver() {
+ cd $pkgbase
+ git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+ arch-meson $pkgbase build \
+ -D docs=true \
+ -D packagekit=false
+ meson compile -C build
+}
+
+check() {
+ meson test -C build --print-errorlogs
+}
+
+_pick() {
+ local p="$1" f d; shift
+ for f; do
+ d="$srcdir/$p/${f#$pkgdir/}"
+ mkdir -p "$(dirname "$d")"
+ mv "$f" "$d"
+ rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+ done
+}
+
+package_nautilus() {
+ depends+=(libnautilus-extension)
+ optdepends=('nautilus-sendto: Send files via mail extension')
+ groups=(gnome)
+
+ DESTDIR="$pkgdir" meson install -C build
+
+### Split libnautilus-extension
+
+ _pick libne "$pkgdir"/usr/include
+ _pick libne "$pkgdir"/usr/lib/{girepository-1.0,libnautilus-extension*,pkgconfig}
+ _pick libne "$pkgdir"/usr/share/{gir-1.0,gtk-doc}
+}
+
+package_libnautilus-extension() {
+ pkgdesc="Library for extending the $pkgdesc"
+ depends=(gtk3)
+ provides=(libnautilus-extension.so)
+ mv libne/* "$pkgdir"
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list