[arch-commits] Commit in (shim shim/repos shim/trunk shim/trunk/PKGBUILD)
David Runge
dvzrv at archlinux.org
Sun Sep 27 19:35:45 UTC 2020
Date: Sunday, September 27, 2020 @ 19:35:44
Author: dvzrv
Revision: 712760
Add shim as possible (yet incomplete) Secure Boot implementation for archiso
Added:
shim/
shim/repos/
shim/trunk/
shim/trunk/PKGBUILD
----------+
PKGBUILD | 34 ++++++++++++++++++++++++++++++++++
1 file changed, 34 insertions(+)
Added: shim/trunk/PKGBUILD
===================================================================
--- shim/trunk/PKGBUILD (rev 0)
+++ shim/trunk/PKGBUILD 2020-09-27 19:35:44 UTC (rev 712760)
@@ -0,0 +1,34 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=shim
+pkgver=15
+pkgrel=4
+pkgdesc="EFI preloader"
+arch=('x86_64')
+url="https://github.com/rhboot/shim"
+license=('BSD')
+makedepends=('git' 'gnu-efi')
+source=("git+https://github.com/rhboot/shim#tag=${pkgver}?signed")
+md5sums=('SKIP')
+validpgpkeys=('B00B48BC731AA8840FED9FB0EED266B70F4FEF10') # Peter Jones <pjones at redhat.com>
+
+prepare() {
+ cd "$pkgname"
+ # -Werror, not even once
+ sed -e 's/-Werror //g' -i Makefile Make.defaults
+}
+
+build() {
+ cd "$pkgname"
+ # TODO: evaluate setting DEFAULT_LOADER to e.g. loader.efi:
+ # this would require changing grub's default, but would allow us to unify
+ make EFI_PATH='/usr/lib/' EFIDIR='ARCH' ENABLE_HTTPBOOT='1'
+}
+
+package() {
+ cd "$pkgname"
+ make DATATARGETDIR="/usr/share/${pkgname}" DESTDIR="$pkgdir/" install-as-data
+ install -vDm 644 COPYRIGHT -t "${pkgdir}/usr/share/licenses/${pkgname}"
+ install -vDm 644 {BUILDING,README,README.{fallback,tpm},TODO} \
+ -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
More information about the arch-commits
mailing list