[arch-commits] Commit in gnome-builder/repos (2 files)
Jan Steffens
heftig at archlinux.org
Sun Sep 27 22:36:45 UTC 2020
Date: Sunday, September 27, 2020 @ 22:36:44
Author: heftig
Revision: 396856
archrelease: copy trunk to gnome-unstable-x86_64
Added:
gnome-builder/repos/gnome-unstable-x86_64/
gnome-builder/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 396854, gnome-builder/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: gnome-builder/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396854, gnome-builder/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2020-09-27 22:36:44 UTC (rev 396856)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=gnome-builder
+pkgver=3.38.0
+pkgrel=1
+pkgdesc="An IDE for writing GNOME-based software"
+url="https://wiki.gnome.org/Apps/Builder"
+arch=(x86_64)
+license=(GPL3)
+depends=(gtksourceview4 devhelp libgit2-glib gjs python-gobject clang
+ desktop-file-utils ctags libpeas vte3 vala python-jedi autoconf-archive
+ flatpak-builder gspell libdazzle template-glib jsonrpc-glib
+ python-sphinx webkit2gtk glade python-lxml meson libportal)
+makedepends=(llvm gobject-introspection gtk-doc yelp-tools appstream-glib git mm-common
+ python-sphinx_rtd_theme)
+checkdepends=(xorg-server-xvfb)
+optdepends=('gnome-code-assistance: Legacy assistance services')
+groups=(gnome-extra)
+_commit=a891fe37c22248c6594a5772d127ed7ba62c5a1c # tags/3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-builder.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^GNOME_BUILDER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+}
+
+build() {
+ arch-meson $pkgname build \
+ -D docs=true \
+ -D plugin_sysprof=false \
+ -D help=true
+ meson compile -C build
+}
+
+check() {
+ dbus-run-session xvfb-run \
+ -s '-screen 0 1920x1080x24 -nolisten local' \
+ meson test -C build --print-errorlogs
+}
+
+package() {
+ depends+=(libgladeui-2.so)
+
+ DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list