[arch-commits] Commit in grilo-plugins/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Sunday, September 27, 2020 @ 23:56:58
  Author: heftig
Revision: 396928

archrelease: copy trunk to staging-x86_64

Added:
  grilo-plugins/repos/staging-x86_64/
  grilo-plugins/repos/staging-x86_64/PKGBUILD
    (from rev 396927, grilo-plugins/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: grilo-plugins/repos/staging-x86_64/PKGBUILD (from rev 396927, grilo-plugins/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-09-27 23:56:58 UTC (rev 396928)
@@ -0,0 +1,43 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=grilo-plugins
+pkgver=0.3.12
+pkgrel=2
+epoch=1
+pkgdesc="A collection of plugins for the Grilo framework"
+url="https://gitlab.gnome.org/GNOME/grilo-plugins"
+arch=(x86_64)
+license=(LGPL)
+depends=(grilo lua libmediaart libgdata tracker3 gom libdmapsharing chromaprint
+         gst-plugins-bad gmime3)
+makedepends=(git meson gperf yelp-tools)
+checkdepends=(gst-plugins-good gst-plugins-base python-gobject tracker3-miners)
+optdepends=('dleyna-server: DLNA plugin'
+            'tracker3-miners: Tracker plugin')
+groups=(gnome)
+_commit=2e8a97e73aed257ef3cbb09340d22478c4cd25e2  # tags/grilo-plugins-0.3.12^0
+source=("git+https://gitlab.gnome.org/GNOME/grilo-plugins.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^grilo-plugins-//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  dbus-run-session meson test -C build --print-errorlogs
+}
+
+package() {
+  depends+=(libgr{ilo,lnet,lpls}-0.3.so)
+  DESTDIR="$pkgdir" meson install -C build
+}