[arch-commits] Commit in haskell-store/repos (2 files)

[Felix Yan]

    Date: Tuesday, September 29, 2020 @ 20:04:05
  Author: felixonmars
Revision: 713808

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-store/repos/community-staging-x86_64/
  haskell-store/repos/community-staging-x86_64/PKGBUILD
    (from rev 713807, haskell-store/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-store/repos/community-staging-x86_64/PKGBUILD (from rev 713807, haskell-store/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-09-29 20:04:05 UTC (rev 713808)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=store
+pkgname=haskell-store
+pkgver=0.7.7
+pkgrel=8
+pkgdesc="Fast binary serialization"
+url="https://github.com/fpco/store"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-base-orphans' 'haskell-base64-bytestring'
+         'haskell-contravariant' 'haskell-cryptohash' 'haskell-free'
+         'haskell-hashable' 'haskell-hspec' 'haskell-hspec-smallcheck' 'haskell-lifted-base'
+         'haskell-monad-control' 'haskell-mono-traversable' 'haskell-network' 'haskell-primitive'
+         'haskell-resourcet' 'haskell-safe' 'haskell-smallcheck'
+         'haskell-store-core' 'haskell-syb' 'haskell-th-lift' 'haskell-th-lift-instances'
+         'haskell-th-orphans' 'haskell-th-reify-many' 'haskell-th-utilities'
+         'haskell-unordered-containers' 'haskell-vector' 'haskell-void')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('fb51d4fc4dea0c0b9be9847edf0ffefc19471b2befcb1d193bbc6c8e0dfbe8f8c9cb647dcb2f2b6db70711e1a77b5b37b8cce930d6bbc4ce2a80ea78adfd4765')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-comparison-bench -f-small-bench
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}