[arch-commits] Commit in (4 files)
Levente Polyak
anthraxx at archlinux.org
Thu Apr 1 00:52:31 UTC 2021
Date: Thursday, April 1, 2021 @ 00:52:30
Author: anthraxx
Revision: 910762
addpkg: rz-ghidra 0.1.1-1
Added:
rz-ghidra/
rz-ghidra/repos/
rz-ghidra/trunk/
rz-ghidra/trunk/PKGBUILD
----------+
PKGBUILD | 59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 59 insertions(+)
Added: rz-ghidra/trunk/PKGBUILD
===================================================================
--- rz-ghidra/trunk/PKGBUILD (rev 0)
+++ rz-ghidra/trunk/PKGBUILD 2021-04-01 00:52:30 UTC (rev 910762)
@@ -0,0 +1,59 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=rz-ghidra
+_gitcommit=8cf6ef09bf8d006f8e194c587be479acf42c6c09
+_gitcutter=e28b2a15b0588dc65d5e1172078be1ae88eab6db
+pkgver=0.1.1
+pkgrel=1
+pkgdesc='Deep ghidra decompiler integration for rizin and rz-cutter'
+url='https://github.com/rizinorg/rz-ghidra'
+arch=('x86_64')
+license=('LGPL3')
+depends=('rizin' 'glibc')
+makedepends=('git' 'cmake' 'qt5-base')
+source=("git+${url}#commit=${_gitcommit}"
+ "git+https://github.com/rizinorg/cutter#commit=${_gitcutter}"
+ rizin-ghidra::git+https://github.com/rizinorg/ghidra.git
+ git+https://github.com/zeux/pugixml.git)
+sha512sums=('SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd ${pkgname}
+ git describe --tags --match 'rz-*' | sed 's/^rz-//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+ cd ${pkgname}
+ git submodule init
+ git config submodule."third-party/pugixml".url "${srcdir}/pugixml"
+ git config submodule."ghidra/ghidra".url "${srcdir}/rizin-ghidra"
+ git submodule update --recursive
+ sed 's|RizinOrg/Cutter|rizin/cutter|g' -i CMakeLists.txt
+}
+
+build() {
+ cd ${pkgname}
+ cmake \
+ -B build \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=None \
+ -DBUILD_CUTTER_PLUGIN=ON \
+ -DBUILD_SLASPECS=ON \
+ -DCUTTER_SOURCE_DIR="${srcdir}/cutter"
+ make -C build VERBOSE=1
+}
+
+package() {
+ cd ${pkgname}
+ make -C build -j1 DESTDIR="${pkgdir}" install
+ # move shared library into RZ_LIBR_PLUGINS
+ rzversion=$(rizin -version|grep rizin|sed -E 's/rizin ([0-9\.]+) .*/\1/')
+ install -d "${pkgdir}/usr/lib/rizin/${rzversion}"
+ mv "${pkgdir}/usr/share/rizin/plugins"/*.so "${pkgdir}/usr/lib/rizin/${rzversion}"
+ ln -s /usr/lib/rizin/${rzversion} "${pkgdir}/usr/lib/rizin/last"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list