[arch-commits] Commit in mutter6/repos (community-x86_64 community-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Thursday, April 1, 2021 @ 15:49:43
  Author: heftig
Revision: 910914

archrelease: copy trunk to community-x86_64

Added:
  mutter6/repos/community-x86_64/
  mutter6/repos/community-x86_64/PKGBUILD
    (from rev 910913, mutter6/trunk/PKGBUILD)

----------+
 PKGBUILD |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

Copied: mutter6/repos/community-x86_64/PKGBUILD (from rev 910913, mutter6/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2021-04-01 15:49:43 UTC (rev 910914)
@@ -0,0 +1,69 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter6
+pkgver=3.36.8
+pkgrel=2
+pkgdesc='A window manager for GNOME'
+url=https://gitlab.gnome.org/GNOME/mutter
+arch=(x86_64)
+license=(GPL2)
+depends=(
+  dconf
+  gnome-desktop
+  gnome-settings-daemon
+  gobject-introspection-runtime
+  gsettings-desktop-schemas
+  libcanberra
+  libgraphene-1.0.so
+  libgudev
+  libinput
+  libsm
+  libxkbcommon-x11
+  libxkbfile
+  pipewire
+  startup-notification
+  upower
+  xorg-server-xwayland
+  zenity
+)
+makedepends=(
+  egl-wayland
+  git
+  gobject-introspection
+  meson
+  xorg-server
+)
+checkdepends=(xorg-server-xvfb)
+provides=(libmutter-6.so)
+_tag=a24048bebb41abf48c3615a945717978f5b7f669
+source=(git+https://gitlab.gnome.org/GNOME/mutter.git#tag=${_tag})
+sha256sums=('SKIP')
+
+pkgver() {
+  cd mutter
+
+  git describe --tags
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+  arch-meson mutter build \
+    --libexecdir /usr/lib/mutter-6 \
+    -D egl_device=true \
+    -D installed_tests=false \
+    -D profiler=false \
+    -D wayland_eglstream=true \
+    -D xwayland_initfd=disabled
+  meson compile -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  rm -rf "${pkgdir}"/usr/{bin,share}
+}
+
+# vim: ts=2 sw=2 et: