[arch-commits] Commit in gnome-initial-setup/repos (2 files)

[Jan Steffens]

    Date: Thursday, April 1, 2021 @ 22:23:10
  Author: heftig
Revision: 910941

archrelease: copy trunk to community-staging-x86_64

Added:
  gnome-initial-setup/repos/community-staging-x86_64/
  gnome-initial-setup/repos/community-staging-x86_64/PKGBUILD
    (from rev 910940, gnome-initial-setup/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: gnome-initial-setup/repos/community-staging-x86_64/PKGBUILD (from rev 910940, gnome-initial-setup/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-04-01 22:23:10 UTC (rev 910941)
@@ -0,0 +1,37 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=gnome-initial-setup
+pkgver=40.0
+pkgrel=1
+pkgdesc="Simple, easy, and safe way to prepare a new system"
+arch=(x86_64)
+url="https://www.gnome.org/"
+license=(GPL)
+depends=(libnma accountsservice cheese gnome-desktop libgweather
+         gnome-online-accounts libgdm libpwquality libibus libgnomekbd
+         geoclue malcontent)
+makedepends=(meson)
+optdepends=('gdm: GDM Initial Setup mode'
+            'gnome-getting-started-docs: GNOME Welcome Tour')
+source=(https://download.gnome.org/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
+sha256sums=('14e0c74614380ee112a7414fec6606bd0f6f3f421b980070ca7d519d1b99896f')
+
+build() {
+  arch-meson $pkgname-$pkgver build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+  install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
+
+  # Setup system user and group
+  echo 'u gnome-initial-setup - "GNOME Initial Setup" /run/gnome-initial-setup' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
+  echo 'd /run/gnome-initial-setup 0700 gnome-initial-setup gnome-initial-setup -' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
+}