[arch-commits] Commit in gnome-panel/repos (2 files)

[Jan Steffens]

    Date: Thursday, April 1, 2021 @ 22:23:24
  Author: heftig
Revision: 910943

archrelease: copy trunk to community-staging-x86_64

Added:
  gnome-panel/repos/community-staging-x86_64/
  gnome-panel/repos/community-staging-x86_64/PKGBUILD
    (from rev 910942, gnome-panel/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: gnome-panel/repos/community-staging-x86_64/PKGBUILD (from rev 910942, gnome-panel/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-04-01 22:23:24 UTC (rev 910943)
@@ -0,0 +1,43 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-panel
+pkgver=3.40.0
+pkgrel=1
+pkgdesc="Panel of GNOME Flashback"
+arch=('x86_64')
+url="https://wiki.gnome.org/Projects/GnomePanel"
+license=('GPL')
+depends=('evolution-data-server' 'gnome-desktop' 'gnome-menus' 'libgdm' 'libwnck3' 'nautilus' 'polkit')
+makedepends=('intltool' 'itstool' 'python' 'git' 'gtk-doc' 'yelp-tools' 'autoconf-archive')
+optdepends=('alacarte: Main menu editor'
+            'gnome-applets: Extra applets for the panel')
+_commit=841fe4e32ff97b7725694dc60828048fa187f758  # tags/3.40.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-panel.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
+              --disable-schemas-compile --enable-compile-warnings=minimum --enable-gtk-doc
+
+  #https://bugzilla.gnome.org/show_bug.cgi?id=656231
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}