[arch-commits] Commit in python-spyder-kernels/repos (2 files)

[Bruno Pagani]

    Date: Friday, April 2, 2021 @ 21:50:09
  Author: archange
Revision: 911236

archrelease: copy trunk to community-testing-any

Added:
  python-spyder-kernels/repos/community-testing-any/
  python-spyder-kernels/repos/community-testing-any/PKGBUILD
    (from rev 911235, python-spyder-kernels/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-spyder-kernels/repos/community-testing-any/PKGBUILD (from rev 911235, python-spyder-kernels/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2021-04-02 21:50:09 UTC (rev 911236)
@@ -0,0 +1,53 @@
+# Maintainer: Muflone http://www.muflone.com/contacts/english/
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=spyder-kernels
+pkgname=python-${_pkg}
+pkgver=2.0.1
+pkgrel=1
+pkgdesc="Jupyter Kernels for the Spyder console"
+arch=(any)
+url="https://github.com/spyder-ide/spyder-kernels/"
+license=(MIT)
+makedepends=(python python-setuptools)
+depends=(
+    python-cloudpickle
+    python-ipykernel
+    python-jupyter_client
+    python-pyzmq
+    python-wurlitzer
+)
+checkdepends=(
+    cython
+    python-dask
+    python-distributed
+    python-flaky
+    python-matplotlib
+    python-mock
+    python-numpy
+    python-pandas
+    python-pillow
+    python-pytest
+    python-scipy
+    python-xarray
+)
+# No tests in pypi tarballs
+#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('dd97f3a43d6d1a2ff2d58a3b46c57d6edd88fa6c93aad3f4e48dd9054bfd5778')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}
+  pytest spyder_kernels
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}