[arch-commits] Commit in python-qdarkstyle/repos (2 files)

[Bruno Pagani]

    Date: Sunday, April 4, 2021 @ 10:49:22
  Author: archange
Revision: 911741

archrelease: copy trunk to community-testing-any

Added:
  python-qdarkstyle/repos/community-testing-any/
  python-qdarkstyle/repos/community-testing-any/PKGBUILD
    (from rev 911740, python-qdarkstyle/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: python-qdarkstyle/repos/community-testing-any/PKGBUILD (from rev 911740, python-qdarkstyle/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2021-04-04 10:49:22 UTC (rev 911741)
@@ -0,0 +1,37 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=QDarkStyle
+pkgname=python-${_pkg,,}
+pkgver=3.0.2
+pkgrel=1
+pkgdesc="Dark style sheet for QtWidgets application"
+arch=(any)
+url="https://github.com/ColinDuquesnoy/QDarkStyleSheet"
+license=(MIT CCPL)
+depends=(python-helpdev python-qtpy)
+makedepends=(python-setuptools)
+checkdepends=(python-pyqt5 pyside2 python-pytest python-pytest-qt)
+# Pypi tarballs do not provide tests files anymore
+#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('a0c13508d2bf0f4919abb9cb5e4c3c8daa768b5da7232af313aeb194d3a61a2f')
+
+build() {
+  cd ${_pkg}Sheet-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}Sheet-${pkgver}
+  # PyQt5 tests
+  python -m qdarkstyle.example --qt_from=pyqt5 --test --offscreen
+  # PySide2 tests, https://github.com/ColinDuquesnoy/QDarkStyleSheet/issues/275
+  sed -i 's|dw_buttons.checkBoxTristate.setCheckState(1)|dw_buttons.checkBoxTristate.setCheckState(QtCore.Qt.Unchecked)|' qdarkstyle/example/__main__.py
+  python -m qdarkstyle.example --qt_from=pyside2 --test --offscreen
+}
+
+package() {
+  cd ${_pkg}Sheet-${pkgver}
+  python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+  install -Dm644 LICENSE.rst -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}