[arch-commits] Commit in dpkg/repos (4 files)

Anatol Pomozov anatolik at archlinux.org
Tue Apr 6 16:05:54 UTC 2021


    Date: Tuesday, April 6, 2021 @ 16:05:54
  Author: anatolik
Revision: 912130

archrelease: copy trunk to community-testing-x86_64

Added:
  dpkg/repos/community-testing-x86_64/
  dpkg/repos/community-testing-x86_64/PKGBUILD
    (from rev 912129, dpkg/trunk/PKGBUILD)
  dpkg/repos/community-testing-x86_64/dpkg.install
    (from rev 912129, dpkg/trunk/dpkg.install)
  dpkg/repos/community-testing-x86_64/origin.archlinux
    (from rev 912129, dpkg/trunk/origin.archlinux)

------------------+
 PKGBUILD         |   60 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 dpkg.install     |    8 +++++++
 origin.archlinux |    3 ++
 3 files changed, 71 insertions(+)

Copied: dpkg/repos/community-testing-x86_64/PKGBUILD (from rev 912129, dpkg/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-04-06 16:05:54 UTC (rev 912130)
@@ -0,0 +1,60 @@
+# Maintainer: Anatol Pomozov
+# Contributor: Alad Wenter <alad (at) archlinux.info>
+# Contributor: Jochen Schalanda <jochen+aur (at) schalanda.name>
+# Contributor: C. Dominik Bódi <dominik.bodi at gmx.de>
+# Contributor: Pierre Carrier <pierre at spotify.com>
+# Contributor: Thomas Dziedzic <gostrc (at) gmail>
+# Contributor: Chris Giles <Chris.G.27 (at) Gmail.com>
+# Contributor: seblu <seblu+arch (at) seblu.net>
+# Contributor: squiddo <squiddo (at) intheocean.net>
+# Contributor: dront78 <dront78 (at) gmail.com>
+# Contributor: hugelgupf <ckoch (at) cs.nmt.edu>
+
+pkgname=dpkg
+pkgver=1.20.7.1
+pkgrel=1
+pkgdesc='The Debian Package Manager tools'
+arch=('x86_64')
+url="https://tracker.debian.org/pkg/dpkg"
+license=('GPL')
+options=('emptydirs')
+depends=('xz' 'zlib' 'bzip2' 'perl')
+makedepends=('perl-io-string' 'perl-timedate' 'git')
+checkdepends=('perl-io-string' 'perl-test-pod')
+install=dpkg.install
+source=(https://salsa.debian.org/dpkg-team/dpkg/-/archive/$pkgver/dpkg-$pkgver.tar.bz2
+        origin.archlinux)
+sha256sums=('a83444ecd04939143a87d8f4af612a9f089c75e881a8f12e5190d012325f6ab3'
+            '193ac1929ea93157c0173db3c871d2f7fe53385391f48078190b03904c5b1f2d')
+
+prepare() {
+    cd dpkg-$pkgver
+    echo "$pkgver" > .dist-version
+    ./autogen
+}
+
+build() {
+    cd dpkg-$pkgver
+    ./configure --prefix=/usr \
+        --sysconfdir=/etc \
+        --localstatedir=/var \
+        --sbindir=/usr/bin \
+        --libexecdir=/usr/lib \
+        --disable-start-stop-daemon
+    make
+}
+
+check() {
+    cd dpkg-$pkgver
+    # make check
+}
+
+package() {
+    cd dpkg-$pkgver
+    make DESTDIR="$pkgdir" install
+    install -Dm644 ../origin.archlinux "$pkgdir"/etc/dpkg/origins/archlinux
+    ln -sf archlinux "$pkgdir"/etc/dpkg/origins/default
+
+    install -d "$pkgdir/var/dpkg"/updates/
+    touch "$pkgdir/var/lib/dpkg"/{status,available}
+}

Copied: dpkg/repos/community-testing-x86_64/dpkg.install (from rev 912129, dpkg/trunk/dpkg.install)
===================================================================
--- community-testing-x86_64/dpkg.install	                        (rev 0)
+++ community-testing-x86_64/dpkg.install	2021-04-06 16:05:54 UTC (rev 912130)
@@ -0,0 +1,8 @@
+post_install() {
+   echo "    dpkg installs Debian package manager."
+   echo "    This is useful for those who want to create/modify DEB files."
+   echo "    However, *do not* use dpkg to install Debian packages in your ArchLinux machine."
+   echo "    This will break your system!"
+   echo "    You will need to go back to Arch wiki and read the installation guide again."
+   echo "    You've been warned!"
+}

Copied: dpkg/repos/community-testing-x86_64/origin.archlinux (from rev 912129, dpkg/trunk/origin.archlinux)
===================================================================
--- community-testing-x86_64/origin.archlinux	                        (rev 0)
+++ community-testing-x86_64/origin.archlinux	2021-04-06 16:05:54 UTC (rev 912130)
@@ -0,0 +1,3 @@
+Vendor: ArchLinux
+Vendor-URL: https://www.archlinux.org/
+Bugs: https://bugs.archlinux.org/



More information about the arch-commits mailing list