[arch-commits] Commit in aom/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Tuesday, April 6, 2021 @ 18:05:18
  Author: heftig
Revision: 411644

archrelease: copy trunk to staging-x86_64

Added:
  aom/repos/staging-x86_64/
  aom/repos/staging-x86_64/PKGBUILD
    (from rev 411643, aom/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: aom/repos/staging-x86_64/PKGBUILD (from rev 411643, aom/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-04-06 18:05:18 UTC (rev 411644)
@@ -0,0 +1,43 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgbase=aom
+pkgname=(aom aom-docs)
+pkgver=3.0.0
+pkgrel=1
+pkgdesc="Alliance for Open Media video codec"
+url="https://aomedia.org/"
+arch=(x86_64)
+license=(BSD custom:PATENTS)
+depends=(gcc-libs)
+makedepends=(git cmake ninja doxygen yasm)
+source=("$pkgbase-$pkgver.tar.gz::https://aomedia.googlesource.com/aom/+archive/v$pkgver.tar.gz")
+b2sums=('572af4b99669f2aff52748446fe985373fdfabe9dedfcc484c8346937a6adb80c60e251126ca529c75f6ace24c6c9a9d71bbf7eede49f07a97fde57ee04494ad')
+
+build() {
+  cmake -S . -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_SHARED_LIBS=1 \
+    -DENABLE_TESTS=0
+  cmake --build build
+}
+
+package_aom() {
+  provides=(libaom.so)
+
+  DESTDIR="$pkgdir" cmake --install build
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE PATENTS
+}
+
+package_aom-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+
+  mkdir -p "$pkgdir/usr/share/doc"
+  cp -r build/docs/html "$pkgdir/usr/share/doc/$pkgname"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE PATENTS
+}
+
+# vim:set et sw=2: