[arch-commits] Commit in (aml aml/trunk aml/trunk/PKGBUILD)

[Maxime Gauduin]

    Date: Saturday, April 10, 2021 @ 07:27:44
  Author: alucryd
Revision: 915410

add aml for neatvnc and wayvnc

Added:
  aml/
  aml/trunk/
  aml/trunk/PKGBUILD

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Added: aml/trunk/PKGBUILD
===================================================================
--- aml/trunk/PKGBUILD	                        (rev 0)
+++ aml/trunk/PKGBUILD	2021-04-10 07:27:44 UTC (rev 915410)
@@ -0,0 +1,37 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Andri Yngvason <andri at yngvason.is>
+
+pkgname=aml
+pkgver=0.2.0
+pkgrel=2
+pkgdesc='Another Main Loop'
+arch=(x86_64)
+url=https://github.com/any1/aml
+license=(custom:ISC)
+depends=(glibc)
+makedepends=(
+  git
+  meson
+  ninja
+)
+provides=(libaml.so)
+_tag=1d8185ec15c68074cec1fd252c01c5ecad877b73
+source=(git+https://github.com/any1/aml.git#tag=${_tag})
+b2sums=(SKIP)
+
+pkgver() {
+  cd aml
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  arch-meson aml build
+  meson compile -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  install -Dm 644 aml/COPYING -t "${pkgdir}"/usr/share/licenses/aml
+}
+
+# vim: ts=2 sw=2 et: