[arch-commits] Commit in (neatvnc neatvnc/trunk neatvnc/trunk/PKGBUILD)

[Maxime Gauduin]

    Date: Saturday, April 10, 2021 @ 07:32:17
  Author: alucryd
Revision: 915412

add neatvnc for wayvnc

Added:
  neatvnc/
  neatvnc/trunk/
  neatvnc/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: neatvnc/trunk/PKGBUILD
===================================================================
--- neatvnc/trunk/PKGBUILD	                        (rev 0)
+++ neatvnc/trunk/PKGBUILD	2021-04-10 07:32:17 UTC (rev 915412)
@@ -0,0 +1,47 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Andri Yngvason <andri at yngvason.is>
+
+pkgname=neatvnc
+pkgver=0.4.0
+pkgrel=2
+pkgdesc='Fast and neat VNC server library'
+arch=(x86_64)
+url=https://github.com/any1/neatvnc
+license=(custom:ISC)
+depends=(
+  glibc
+  gnutls
+  libaml.so
+  libpixman-1.so
+  libturbojpeg.so
+  zlib
+)
+makedepends=(
+  git
+  libdrm
+  meson
+  ninja
+)
+provides=(libneatvnc.so)
+_tag=b1d32694d0a310e36da1cf84420c827bbf665755
+source=(git+https://github.com/any1/neatvnc.git#tag=${_tag})
+b2sums=(SKIP)
+
+pkgver() {
+  cd neatvnc
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  arch-meson neatvnc build \
+    -Djpeg=enabled \
+    -Dtls=enabled
+  meson compile -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  install -Dm 644 neatvnc/COPYING -t "${pkgdir}"/usr/share/licenses/neatvnc
+}
+
+# vim: ts=2 sw=2 et: