[arch-commits] Commit in wayvnc (4 files)

[Maxime Gauduin]

    Date: Saturday, April 10, 2021 @ 07:37:11
  Author: alucryd
Revision: 915415

archrelease: copy trunk to community-x86_64

Added:
  wayvnc/repos/
  wayvnc/repos/community-x86_64/
  wayvnc/repos/community-x86_64/PKGBUILD
    (from rev 915414, wayvnc/trunk/PKGBUILD)
  wayvnc/repos/community-x86_64/wayvnc.service
    (from rev 915414, wayvnc/trunk/wayvnc.service)

----------------+
 PKGBUILD       |   56 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 wayvnc.service |   14 +++++++++++++
 2 files changed, 70 insertions(+)

Copied: wayvnc/repos/community-x86_64/PKGBUILD (from rev 915414, wayvnc/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2021-04-10 07:37:11 UTC (rev 915415)
@@ -0,0 +1,56 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Andri Yngvason <andri at yngvason.is>
+
+pkgname=wayvnc
+pkgver=0.4.0
+pkgrel=2
+pkgdesc='VNC server for wlroots-based Wayland compositors'
+arch=(x86_64)
+url=https://github.com/any1/wayvnc
+license=(custom:ISC)
+depends=(
+  glibc
+  libaml.so
+  libdrm
+  libneatvnc.so
+  libpixman-1.so
+  libxkbcommon.so
+  wayland
+)
+makedepends=(
+  git
+  meson
+  ninja
+  pam
+  scdoc
+)
+optdepends=('pam: PAM authentication')
+_tag=13323a742f1449355852b2501b25d8df804cefee
+source=(
+  git+https://github.com/any1/wayvnc.git#tag=${_tag}
+  wayvnc.service
+)
+b2sums=(
+  SKIP
+  083d7ddbf353d06126b76152e51807ed7572684e0c995b71802fcf36ca133c48401126907fcac657271bf9590b4a304a103f7bf9104b73e0699af98f7388f65c
+)
+
+pkgver() {
+  cd wayvnc
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  arch-meson wayvnc build \
+    -Dman-pages=enabled \
+    -Dpam=enabled
+  meson compile -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  install -Dm 644 wayvnc.service -t "${pkgdir}"/usr/lib/systemd/user
+  install -Dm 644 wayvnc/COPYING -t "${pkgdir}"/usr/share/licenses/wayvnc
+}
+
+# vim: ts=2 sw=2 et:

Copied: wayvnc/repos/community-x86_64/wayvnc.service (from rev 915414, wayvnc/trunk/wayvnc.service)
===================================================================
--- repos/community-x86_64/wayvnc.service	                        (rev 0)
+++ repos/community-x86_64/wayvnc.service	2021-04-10 07:37:11 UTC (rev 915415)
@@ -0,0 +1,14 @@
+[Unit]
+Description=A VNC server for wlroots based Wayland compositors
+Requires=sway.service
+After=sway.service
+
+[Service]
+Type=simple
+ExecStart=/usr/bin/wayvnc
+Restart=on-failure
+RestartSec=1
+TimeoutStopSec=10
+
+[Install]
+WantedBy=multi-user.target