[arch-commits] Commit in lib32-harfbuzz/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Thu Apr 15 13:49:08 UTC 2021
Date: Thursday, April 15, 2021 @ 13:49:08
Author: felixonmars
Revision: 919060
archrelease: copy trunk to multilib-staging-x86_64
Added:
lib32-harfbuzz/repos/multilib-staging-x86_64/
lib32-harfbuzz/repos/multilib-staging-x86_64/PKGBUILD
(from rev 919059, lib32-harfbuzz/trunk/PKGBUILD)
----------+
PKGBUILD | 70 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 70 insertions(+)
Copied: lib32-harfbuzz/repos/multilib-staging-x86_64/PKGBUILD (from rev 919059, lib32-harfbuzz/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD (rev 0)
+++ multilib-staging-x86_64/PKGBUILD 2021-04-15 13:49:08 UTC (rev 919060)
@@ -0,0 +1,70 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Florian Pritz <bluewind at xinu.at>
+
+pkgbase=lib32-harfbuzz
+pkgname=(lib32-harfbuzz lib32-harfbuzz-icu)
+pkgver=2.8.0
+pkgrel=2
+pkgdesc="OpenType text shaping engine (32-bit)"
+url="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+arch=(x86_64)
+license=(MIT)
+makedepends=(lib32-glib2 lib32-freetype2 lib32-cairo lib32-icu ragel git python
+ meson harfbuzz)
+checkdepends=(python-fonttools python-setuptools)
+_commit=03538e872a0610a65fad692b33d3646f387cf578 # tags/2.8.0^0
+source=("git+https://github.com/harfbuzz/harfbuzz#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd harfbuzz
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd harfbuzz
+}
+
+build() {
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+ arch-meson harfbuzz build \
+ --libdir=/usr/lib32 \
+ -D introspection=disabled \
+ -D docs=disabled
+ meson compile -C build
+}
+
+check() {
+ mkdir -p tmp
+ TMPDIR="$PWD/tmp" meson test -C build --print-errorlogs
+ rm -r tmp
+}
+
+package_lib32-harfbuzz() {
+ depends=(lib32-glib2 lib32-freetype2 libglib-2.0.so libfreetype.so
+ libgobject-2.0.so harfbuzz)
+ provides=(libharfbuzz.so libharfbuzz-subset.so libharfbuzz-gobject.so)
+
+ DESTDIR="$pkgdir" meson install -C build
+ rm -rf "${pkgdir}"/usr/{include,share,bin}
+
+ # Split harfbuzz-icu
+ mkdir -p hb-icu/usr/lib32/pkgconfig
+ mv -t hb-icu/usr/lib32 "$pkgdir"/usr/lib32/libharfbuzz-icu*
+ mv -t hb-icu/usr/lib32/pkgconfig "$pkgdir"/usr/lib32/pkgconfig/harfbuzz-icu.pc
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}
+
+package_lib32-harfbuzz-icu() {
+ pkgdesc="$pkgdesc (ICU integration)"
+ depends=("lib32-harfbuzz=$pkgver-$pkgrel" lib32-icu libharfbuzz.so harfbuzz-icu)
+ provides=(libharfbuzz-icu.so)
+
+ mv hb-icu/* "$pkgdir"
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}
More information about the arch-commits
mailing list