[arch-commits] Commit in nodejs/repos (3 files)
Felix Yan
felixonmars at archlinux.org
Tue Apr 20 17:38:05 UTC 2021
Date: Tuesday, April 20, 2021 @ 17:38:05
Author: felixonmars
Revision: 920120
archrelease: copy trunk to community-testing-x86_64
Added:
nodejs/repos/community-testing-x86_64/
nodejs/repos/community-testing-x86_64/PKGBUILD
(from rev 920119, nodejs/trunk/PKGBUILD)
nodejs/repos/community-testing-x86_64/rebuild.list
(from rev 920119, nodejs/trunk/rebuild.list)
--------------+
PKGBUILD | 57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
rebuild.list | 2 ++
2 files changed, 59 insertions(+)
Copied: nodejs/repos/community-testing-x86_64/PKGBUILD (from rev 920119, nodejs/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2021-04-20 17:38:05 UTC (rev 920120)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: James Campos <james.r.campos at gmail.com>
+# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
+# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
+# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
+# Contributor: TIanyi Cui <tianyicui at gmail.com>
+
+pkgname=nodejs
+pkgver=16.0.0
+pkgrel=1
+pkgdesc='Evented I/O for V8 javascript'
+arch=('x86_64')
+url='https://nodejs.org/'
+license=('MIT')
+# c-ares: wait until a newer release than 1.16.1
+depends=('openssl' 'zlib' 'icu' 'libuv' 'libnghttp2') # 'c-ares' 'http-parser' 'v8')
+makedepends=('python' 'procps-ng')
+optdepends=('npm: nodejs package manager')
+source=("https://github.com/nodejs/node/archive/v$pkgver/nodejs-$pkgver.tar.gz")
+sha512sums=('606d283307e463f7bd91ad42be3d4d194ee57dd1e1c3a29e87ada0d4de70186b3920758f567f09fe5f93a0ceed92d485dd372074974d176c4eef0b6678102c3e')
+
+build() {
+ cd node-$pkgver
+
+ ./configure \
+ --prefix=/usr \
+ --with-intl=system-icu \
+ --without-npm \
+ --shared-openssl \
+ --shared-zlib \
+ --shared-libuv \
+ --experimental-http-parser \
+ --shared-nghttp2
+ # --shared-cares
+ # --shared-v8
+ # --shared-http-parser
+
+ make
+}
+
+check() {
+ cd node-$pkgver
+ make test || :
+}
+
+package() {
+ cd node-$pkgver
+
+ make DESTDIR="$pkgdir" install
+
+ install -D -m644 LICENSE \
+ "$pkgdir"/usr/share/licenses/nodejs/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
Copied: nodejs/repos/community-testing-x86_64/rebuild.list (from rev 920119, nodejs/trunk/rebuild.list)
===================================================================
--- community-testing-x86_64/rebuild.list (rev 0)
+++ community-testing-x86_64/rebuild.list 2021-04-20 17:38:05 UTC (rev 920120)
@@ -0,0 +1,2 @@
+apm
+bash-language-server
More information about the arch-commits
mailing list